Send Email with Attachments

Create and send an email with file attachments.

Download Chilkat Email ActiveX

Download 32-bit Chilkat IMAP ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

'  The mailman object is used for sending and receiving email.
set mailman = CreateObject("Chilkat.MailMan2")

'  Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    WScript.Quit
End If

'  Set the SMTP server.
mailman.SmtpHost = "smtp.chilkatsoft.com"

'  You may need a login/password.  In many cases,
'  authentication is not required when sending local email
'  (i.e. to email addresses having the same domain as the
'  SMTP server), but is required when sending to non-local
'  recipients.
mailman.SmtpUsername = "myLogin"
mailman.SmtpPassword = "myPassword"

'  Create a new email object
set email = CreateObject("Chilkat.Email2")

email.Subject = "This is a test"
email.Body = "This is a test"
email.From = "Chilkat Support <support@chilkatsoft.com>"
email.AddTo "Somebody1","somebody1@somewhere.com"
email.AddTo "Somebody2","somebody2@somewhere.com"

'  Add any number of attachments:

'  The AddFileAttachment method can be called any number of times
'  to add 1 or more attachments to an email.  It returns the
'  content type of the attachment added.  This is for informational
'  purposes only.  For example, if a .jpg file is attached,
'  the return string will be "image/jpeg".
'  If AddFileAttachment fails (perhaps by a file-not-found error),
'  a NULL reference is returned:
contentType = email.AddFileAttachment("c:/temp/something.doc")
If (contentType = vbNullString ) Then
    MsgBox email.LastErrorText
    WScript.Quit
End If

success = mailman.SendEmail(email)
If (success <> 1) Then
    MsgBox mailman.LastErrorText
Else
    MsgBox "Mail Sent!"
End If