Send Email with Inline Attachment

Download Chilkat Email ActiveX

Create an send an email with an inline attachment.

'  The mailman object is used for sending and receiving email.
set mailman = CreateObject("Chilkat.MailMan2")

'  Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    WScript.Quit
End If

'  Set the SMTP server.
mailman.SmtpHost = "smtp.chilkatsoft.com"

'  You may need a login/password.  In many cases,
'  authentication is not required when sending local email
'  (i.e. to email addresses having the same domain as the
'  SMTP server), but is required when sending to non-local
'  recipients.
mailman.SmtpUsername = "myLogin"
mailman.SmtpPassword = "myPassword"

'  Create a new email object
set email = CreateObject("Chilkat.Email2")

email.Subject = "This is a test"
email.Body = "This is a test"
email.From = "Chilkat Support <support@chilkatsoft.com>"
email.AddTo "Chilkat Admin","admin@chilkatsoft.com"

'  Add any number of attachments:

contentType = email.AddFileAttachment("c:/temp/dude.gif")
If (contentType = vbNullString ) Then
    MsgBox email.LastErrorText
    WScript.Quit
End If

'  Update the content-disposition header field for the attachment
'  so that it's sent inline:
'  AddAttachmentHeader replaces the header field if it already
'  exists.
email.AddAttachmentHeader 0,"content-disposition","inline; filename=""dude.gif"""

success = mailman.SendEmail(email)
If (success <> 1) Then
    MsgBox mailman.LastErrorText
Else
    MsgBox "Mail Sent!"
End If