Select Cert for Encrypted Email

Demonstrates how to search for a specific certificate from Current User and Local Machine certificate stores, and then use it for encrypting an email.

Download Chilkat Email ActiveX for POP3 / SMTP

Download Chilkat IMAP ActiveX

'  The mailman object is used for sending and receiving email.
set mailman = CreateObject("Chilkat.MailMan2")

'  Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    WScript.Quit
End If

'  Set the SMTP server.
mailman.SmtpHost = "smtp.comcast.net"

'  Search the Local Machine and Current User certificate
'  stores for a certificate -- by common name or by email  address.
set cert = CreateObject("Chilkat.Cert")

success = cert.LoadByCommonName("Chilkat Software")
If (success <> 1) Then
    '  Try loading it by email address.
    success = cert.LoadByEmailAddress("comodo@chilkatsoft.com")
    If (success <> 1) Then
        MsgBox cert.LastErrorText
        WScript.Quit
    End If

End If

'  Create a new email object
set email = CreateObject("Chilkat.Email2")

email.Subject = "This email is encrypted"
email.Body = "This is a digitally encrypted mail"
email.From = "Chilkat Support <support@chilkatsoft.com>"
email.AddTo "Comodo Test","comodo@chilkatsoft.com"

'  Indicate that the email is to be sent encrypted.
email.SendEncrypted = 1

'  Specify the certificate:
success = email.SetEncryptCert(cert)
If (success <> 1) Then
    MsgBox email.LastErrorText
    WScript.Quit
End If

success = mailman.SendEmail(email)
If (success <> 1) Then
    MsgBox mailman.LastErrorText
Else
    MsgBox "Mail Sent!"
End If