Send Identical Email to Distribution List

Sends an identical email to a distribution list.

Download Chilkat Email ActiveX

Download Chilkat IMAP ActiveX

'  The mailman object is used for sending and receiving email.
set mailman = CreateObject("Chilkat.MailMan2")

'  Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    WScript.Quit
End If

'  Set the SMTP server.
mailman.SmtpHost = "mail.chilkatsoft.com"
mailman.SmtpUsername = "admin@chilkatsoft.com"
mailman.SmtpPassword = "****"

'  Create a new email object
set email = CreateObject("Chilkat.Email2")

email.Subject = "This is a test"
email.Body = "This is a test"
email.From = "Chilkat Support <support@chilkatsoft.com>"

'  Load a text file containing email addresses, one per line,
'  into a StringArray object. (In some programming languages,
'  this is a CkStringArray.)
set sa = CreateObject("Chilkat.CkStringArray")
success = sa.LoadFromFile("distributionList.txt")
If (success <> 1) Then
    MsgBox "Failed to load distributionList.txt"
    WScript.Quit
End If

'  Note: the distributionList.txt file contains one email
'  address per line.  For example:
' 
'  matt@chilkatsoft.com
'  "Chilkat Admin" <admin@chilkatsoft.com>
'  <support@chilkatsoft.com>
' 
'  An email address may contain both the friendly name (in quote)
'  and the email address (in angled brackets).  The friendly
'  name is optional.  When the friendly name is missing,
'  angled brackets are optional.

'  If the SendIndividual property is 1, then the email
'  is sent individually to each recipient in the list using
'  the "To" header field.

'  If the SendIndividual property is 0, then emails
'  are sent in batches of 100 BCC's.  Your program should
'  provide a single "To" address, such as:
email.AddTo "My List","listAdmin@chilkatsoft.com"

'  This example will send emails individually, so we'll clear
'  the "To" list.
email.ClearTo 

'  Set the mailman's SendIndividual property = 1
mailman.SendIndividual = 1

success = mailman.SendToDistributionList(email,sa)
If (success <> 1) Then
    MsgBox mailman.LastErrorText
Else
    MsgBox "Mail Sent!"
End If