Embed Image in HTML Email

Download Chilkat Email ActiveX

Demonstrates how to create and send an HTML email with an embedded image.

' The mailman object is used for sending and receiving email.
set mailman = CreateObject("Chilkat.MailMan2")

' Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    WScript.Quit
End If

' Set the SMTP server.
mailman.SmtpHost = "smtp.comcast.net"

' Create a new email object
set email = CreateObject("Chilkat.Email2")

' Add an embedded image to the HTML email.
fileOnDisk = "images/dude2.gif"
filePathInHtml = "something/dudeAbc.gif"

' Embed the GIF image in the email.
success = email.AddRelatedFile2(fileOnDisk,filePathInHtml)
If (success <> 1) Then
    MsgBox email.LastErrorText
    WScript.Quit
End If

' The src attribute for the image tag is set to the filePathInHtml:
htmlBody = "<html><body>Embedded Image:<br><img src=""something/dudeAbc.gif""></body></html>"

' Set the basic email stuff: HTML body, subject, "from", "to"
email.SetHtmlBody htmlBody
email.Subject = "VBScript HTML email with an embedded image."
email.AddTo "Admin","admin@chilkatsoft.com"
email.From = "Chilkat Support <support@chilkatsoft.com>"

success = mailman.SendEmail(email)
If (success <> 1) Then
    MsgBox mailman.LastErrorText
Else
    MsgBox "Mail Sent!"
End If

Mail Component · XML Parser