Create Detached Signature using PFX

Download Chilkat Crypt ActiveX

Creates and verifies a detached signature.

set crypt = CreateObject("Chilkat.Crypt2")

'  Any string argument automatically begins the 30-day trial.
success = crypt.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Crypt component unlock failed"
    WScript.Quit
End If

'  Create an instance of a certificate store object, load a PFX file,
'  locate the certificate we need, and use it for signing.
'  (a PFX file may contain more than one certificate.)
set certStore = CreateObject("Chilkat.CertStore")
'  The 1st argument is the filename, the 2nd arg is the
'  PFX file's password:
success = certStore.LoadPfxFile("chilkat.pfx","test")
If (success <> 1) Then
    MsgBox certStore.LastErrorText
    WScript.Quit
End If

Set cert = certStore.FindCertBySubject("Chilkat Software, Inc.")
If (cert Is Nothing ) Then
    MsgBox certStore.LastErrorText
    WScript.Quit
End If

'  Tell the crypt component to use this cert.
crypt.SetSigningCert cert

'  We can sign any type of file, creating a .sig as output:
success = crypt.CreateDetachedSignature("test.pdf","test.sig")
If (success = 1) Then
    MsgBox "Success!"
End If

MsgBox crypt.LastErrorText

'  Verify and restore the original file:
crypt.SetVerifyCert cert

success = crypt.VerifyDetachedSignature("test.pdf","test.sig")
If (success = 1) Then
    MsgBox "Success!"
End If

MsgBox crypt.LastErrorText