Streaming SFTP Download

Demonstrates how to download a file chunk by chunk from an SSH server.

Download Chilkat SSH / SFTP ActiveX

'  Important: It is helpful to send the contents of the
'  sftp.LastErrorText property when requesting support.

set sftp = CreateObject("Chilkat.SFtp")

'  Any string automatically begins a fully-functional 30-day trial.
success = sftp.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    WScript.Quit
End If

'  Set some timeouts, in milliseconds:
sftp.ConnectTimeoutMs = 5000
sftp.IdleTimeoutMs = 15000

'  Connect to the SSH server.
'  The standard SSH port = 22
'  The hostname may be a hostname or IP address.

hostname = "www.my-ssh-server.com"
port = 22
success = sftp.Connect(hostname,port)
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    WScript.Quit
End If

'  Authenticate with the SSH server.  Chilkat SFTP supports
'  both password-based authenication as well as public-key
'  authentication.  This example uses password authenication.
success = sftp.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    WScript.Quit
End If

'  After authenticating, the SFTP subsystem must be initialized:
success = sftp.InitializeSftp()
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    WScript.Quit
End If

'  Open a file on the server:

handle = sftp.OpenFile("hamlet.xml","readOnly","openExisting")
If (handle = vbNullString ) Then
    MsgBox sftp.LastErrorText
    WScript.Quit
End If

bEof = 0
chunkSize = 10000

Do While bEof = 0

    pData = sftp.ReadFileBytes(handle,chunkSize)
    If (sftp.LastReadFailed(handle) = 1) Then
        MsgBox sftp.LastErrorText
        Exit Do
    Else

        '  Do whatever  you wish with the data received...
        '  It is possible that if the EOF is reached, 0 bytes will be returned.

    End If

    bEof = sftp.Eof(handle)
Loop

'  Close the file.
success = sftp.CloseHandle(handle)
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    WScript.Quit
End If

MsgBox "Success."