SFTP Resume Download

Demonstrates how to resume an SFTP download from a previous partial download.

Download Chilkat SSH / SFTP ActiveX

'  Important: It is helpful to send the contents of the
'  sftp.LastErrorText property when requesting support.

set sftp = CreateObject("Chilkat.SFtp")

'  Any string automatically begins a fully-functional 30-day trial.
success = sftp.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    WScript.Quit
End If

'  Set some timeouts, in milliseconds:
sftp.ConnectTimeoutMs = 5000
sftp.IdleTimeoutMs = 10000

'  Connect to the SSH server.
'  The standard SSH port = 22
'  The hostname may be a hostname or IP address.

hostname = "www.my-ssh-server.com"
port = 22
success = sftp.Connect(hostname,port)
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    WScript.Quit
End If

'  Authenticate with the SSH server.  Chilkat SFTP supports
'  both password-based authenication as well as public-key
'  authentication.  This example uses password authenication.
success = sftp.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    WScript.Quit
End If

'  After authenticating, the SFTP subsystem must be initialized:
success = sftp.InitializeSftp()
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    WScript.Quit
End If

'  Download the file:

localFilePath = "c:/temp/hamlet.xml"
remoteFilePath = "subdir1/subdir2/hamlet.xml"
'  The ResumeDownloadFileByName method will check
'  the local file and begin downloading the remote file
'  at the appropriate point.  For example, if the local
'  file is already 215624 bytes long, it will begin downloading
'  the remote file at the 215625'th byte -- appending to
'  the local file.
success = sftp.ResumeDownloadFileByName(remoteFilePath,localFilePath)
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    WScript.Quit
End If

MsgBox "Success."