SFTP Read Directory Listing

Demonstrates how to download a directory listing and iterate over the files.

Download Chilkat SSH / SFTP ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

'  Important: It is helpful to send the contents of the
'  sftp.LastErrorText property when requesting support.

set sftp = CreateObject("Chilkat.SFtp")

'  Any string automatically begins a fully-functional 30-day trial.
success = sftp.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    WScript.Quit
End If

'  Set some timeouts, in milliseconds:
sftp.ConnectTimeoutMs = 5000
sftp.IdleTimeoutMs = 10000

'  Connect to the SSH server.
'  The standard SSH port = 22
'  The hostname may be a hostname or IP address.

hostname = "www.my-sftp-server.com"
port = 22
success = sftp.Connect(hostname,port)
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    WScript.Quit
End If

'  Authenticate with the SSH server.  Chilkat SFTP supports
'  both password-based authenication as well as public-key
'  authentication.  This example uses password authenication.
success = sftp.AuthenticatePw("myLogin","myPassword")
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    WScript.Quit
End If

'  After authenticating, the SFTP subsystem must be initialized:
success = sftp.InitializeSftp()
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    WScript.Quit
End If

'  Open a directory on the server...
'  Paths starting with a slash are "absolute", and are relative
'  to the root of the file system. Names starting with any other
'  character are relative to the user's default directory (home directory).
'  A path component of ".." refers to the parent directory,
'  and "." refers to the current directory.

handle = sftp.OpenDir(".")
If (handle = vbNullString ) Then
    MsgBox sftp.LastErrorText
    WScript.Quit
End If

'  Download the directory listing:

' dirListing is a Chilkat.SFtpDir
Set dirListing = sftp.ReadDir(handle)
If (dirListing Is Nothing ) Then
    MsgBox sftp.LastErrorText
    WScript.Quit
End If

'  Iterate over the files.

n = dirListing.NumFilesAndDirs
If (n = 0) Then
    outFile.WriteLine("No entries found in this directory.")
Else
    For i = 0 To n - 1

        ' fileObj is a Chilkat.SFtpFile
        Set fileObj = dirListing.GetFileObject(i)

        outFile.WriteLine(fileObj.Filename)
        outFile.WriteLine(fileObj.FileType)
        outFile.WriteLine("Size in bytes: " & fileObj.Size32)
        outFile.WriteLine("----")

    Next
End If

'  Close the directory
success = sftp.CloseHandle(handle)
If (success <> 1) Then
    MsgBox sftp.LastErrorText
    WScript.Quit
End If

MsgBox "Success."
outFile.Close