Amazon S3 - Delete Bucket (REST API)

Deletes an Amazon S3 bucket using the REST API. This example deletes the bucket named "chilkat3".

Download Chilkat XML ActiveX

Download Chilkat Crypt ActiveX

Download Chilkat HTTP ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set http = CreateObject("Chilkat.Http")
success = http.UnlockComponent("Anything for 30-day trial.")
If (success <> 1) Then
    '  Unlock failed.
    MsgBox http.LastErrorText
    WScript.Quit
End If

set crypt = CreateObject("Chilkat.Crypt2")

success = crypt.UnlockComponent("Anything for 30-day trial.")
If (success <> 1) Then
    MsgBox crypt.LastErrorText
    WScript.Quit
End If

'  The HTTP component now includes a method to generate
'  the current date/time in RFC 2616 compliant format.
'  Note: The GenTimeStamp method is available as a pre-release (as of 18-June-2008).
'  It will become available in the next new version dated after
'  18-June-2008.
curDateTime = http.GenTimeStamp()

'  Delete the bucket named "chilkat3"
strToSign = "DELETE" & vbLf & vbLf & vbLf & curDateTime & vbLf & "/chilkat3/"

'  We want SHA1 for the HMAC hash algorithm:
crypt.HashAlgorithm = "sha1"

'  These must be changed for your account:
AWSAccessKeyId = "zzzzzzzzzzzzzzzzzzzzz"
AWSSecretAccessKey = "zzzzzzzzzzzzzzzzzzzzzzzzzzz"

'  Set the HMAC secret key:
crypt.SetHmacKeyString AWSSecretAccessKey

'  By setting the charset = "utf-8", the string will be converted
'  to utf-8 (internal to the Chilkat component) prior to signing:
crypt.Charset = "utf-8"

'  Indicate that Base64 output is desired:
crypt.EncodingMode = "base64"

signature = crypt.HmacStringENC(strToSign)

authValue = "AWS " & AWSAccessKeyId & ":" & signature

'  The bucket to be deleted is specified in the Host header.
'  In this example, the "chilkat3" bucket is deleted
http.SetRequestHeader "Host","chilkat3.s3.amazonaws.com"

http.SetRequestHeader "Authorization",authValue
http.SetRequestHeader "Date",curDateTime

'  Send the DELETE request.

responseStr = http.QuickDeleteStr("http://s3.amazonaws.com/")

If (responseStr = vbNullString ) Then
    '  Failed.  Show the last request header, response header,
    '  and response body.
    outFile.WriteLine(http.LastHeader)
    outFile.WriteLine("---")
    outFile.WriteLine(http.LastResponseHeader)
    outFile.WriteLine("---")
    outFile.WriteLine(http.LastErrorText)
Else

    '  Success is indicated by an empty response string, and
    '  a response status of 204.
    If (http.LastStatus = 204) Then
        MsgBox "Bucket deleted!"

        '  Let's check out the response header anyway...
        outFile.WriteLine(http.LastResponseHeader)

    Else

        '  Is this a temporary redirect?
        If (http.LastStatus = 307) Then

            '  The new endpoint is in the XML contained within responseStr.
            set xml = CreateObject("Chilkat.Xml")
            xml.LoadXml responseStr
            endpoint = xml.GetChildContent("Endpoint")
            responseStr = http.QuickDeleteStr(endpoint)
            If (http.LastStatus = 204) Then
                MsgBox "Bucket deleted after redirect!"

                '  Let's check out the response header anyway...
                outFile.WriteLine(http.LastResponseHeader)

            Else
                '  What happened???
                outFile.WriteLine("LastStatus: " _
                     & http.LastStatus)
                outFile.WriteLine("---")
                outFile.WriteLine(responseStr)
                outFile.WriteLine("---")
                outFile.WriteLine(http.LastHeader)
                outFile.WriteLine("---")
                outFile.WriteLine(http.LastResponseHeader)
                outFile.WriteLine("---")
                outFile.WriteLine(http.LastErrorText)
            End If

        Else
            '  What response is this???
            outFile.WriteLine("LastStatus: " _
                 & http.LastStatus)
            outFile.WriteLine("---")
            outFile.WriteLine(responseStr)
            outFile.WriteLine("---")
            '  Failed.  Show the last request header, response header,
            '  and response body.
            outFile.WriteLine(http.LastHeader)
            outFile.WriteLine("---")
            outFile.WriteLine(http.LastResponseHeader)
            outFile.WriteLine("---")
            outFile.WriteLine(http.LastErrorText)
        End If

    End If

End If

outFile.Close