RSA Signature with Certificate's Private Key from PFX

Demonstrates how to use a certificate's private key from a PFX file to create an RSA signature.

Download 32-bit Chilkat RSA ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)



'  Create an instance of a certificate store object, load a PFX file,
'  locate the certificate we need, and use it for signing.
'  (a PFX file may contain more than one certificate.)
set certStore = CreateObject("Chilkat.CertStore")

'  The 1st argument is the filename, the 2nd arg is the
'  PFX file's password:
success = certStore.LoadPfxFile("chilkat.pfx","test")
If (success <> 1) Then
    MsgBox certStore.LastErrorText
    WScript.Quit
End If

' cert is a Chilkat.Cert
Set cert = certStore.FindCertBySubject("Chilkat Software, Inc.")
If (cert Is Nothing ) Then
    MsgBox certStore.LastErrorText
    WScript.Quit
End If

' pkey is a Chilkat.PrivateKey
Set pkey = cert.ExportPrivateKey()
If (pkey Is Nothing ) Then
    MsgBox cert.LastErrorText
    WScript.Quit
End If

'  Get the private key in XML format:
pkeyXml = pkey.GetXml()

set rsa = CreateObject("Chilkat.Rsa")

'  Any string argument automatically begins the 30-day trial.
success = rsa.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "RSA component unlock failed"
    WScript.Quit
End If

'  Import the private key into the RSA component:
success = rsa.ImportPrivateKey(pkeyXml)
If (success <> 1) Then
    MsgBox rsa.LastErrorText
    WScript.Quit
End If

'  This example will sign a string, and receive the signature
'  in a hex-encoded string.  Therefore, set the encoding mode
'  to "hex":
rsa.EncodingMode = "hex"

'  If some other non-Chilkat application or web service is going to be verifying
'  the signature, it is important to match the byte-ordering.
'  The LittleEndian property may be set to 1
'  for little-endian byte ordering,
'  or 0  for big-endian byte ordering.
'  Microsoft apps typically use little-endian, while
'  OpenSSL and other services (such as Amazon CloudFront)
'  use big-endian.
rsa.LittleEndian = 0

strData = "This is the string to be signed."

'  Sign the string using the sha-1 hash algorithm.
'  Other valid choices are "md2" and "md5".
hexSig = rsa.SignStringENC(strData,"sha-1")

outFile.WriteLine(hexSig)

MsgBox "Success!"
outFile.Close