Create PKCS1 RSA Signature with PEM Private Key

Demonstrates how to load a private key from a PEM file and create a PKCS1 RSA digital signature.

Download 32-bit Chilkat RSA ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set pkey = CreateObject("Chilkat.PrivateKey")

'  Load the private key from an RSA PEM file:
pkey.LoadPemFile "pvkey2_rsa.pem"

'  Get the private key in XML format:
pkeyXml = pkey.GetXml()

set rsa = CreateObject("Chilkat.Rsa")

'  Any string argument automatically begins the 30-day trial.
success = rsa.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "RSA component unlock failed"
    WScript.Quit
End If

'  Import the private key into the RSA component:
success = rsa.ImportPrivateKey(pkeyXml)
If (success <> 1) Then
    MsgBox rsa.LastErrorText
    WScript.Quit
End If

'  This example will sign a string, and receive the signature
'  in a hex-encoded string.  Therefore, set the encoding mode
'  to "hex":
rsa.EncodingMode = "hex"

'  If some other non-Chilkat software is going to verify
'  the signature, it is important to match the byte-ordering.
'  The LittleEndian property may be set to 1
'  for little-endian byte ordering,
'  or 0  for big-endian byte ordering.
'  Microsoft apps typically use little-endian, while
'  OpenSSL and other services (such as Amazon CloudFront)
'  use big-endian.
rsa.LittleEndian = 0

strData = "This is the string to be signed."

'  Sign the string using the sha-1 hash algorithm.
'  Other valid choices are "md2", "md5", "sha256",
'  "sha384", and "sha512".
hexSig = rsa.SignStringENC(strData,"sha-1")

outFile.WriteLine(hexSig)

MsgBox "Success!"
outFile.Close