Duplicating OpenSSL rsautl (creating RSA signatures)

Demonstrates how to duplicate OpenSSL rsautil RSA signatures.

The Chilkat RSA component's methods for creating RSA signatures (SignBytes, SignBytesENC, SignString, and SignStringENC) are very different from OpenSSL's rsautl command. First, we'll explain what Chilkat's signing methods do, and then what OpenSSL's rsautl does. New signing methods have been added to Chilkat RSA to duplicate OpenSSL rsautl: OpenSslSignBytes, OpenSslSignBytesENC, OpenSslSignString, and OpenSslSignStringENC.

Here's what Chilkat's RSA Sign* methods do:
(Note: Chilkat RSA's Sign* methods generate signatures according to RSA Laboratories' "PKCS #1 v2.0: RSA Cryptography Standard".)

1. Input data is hashed using the hashing algorithm specified.
2. The hash is padded using either PKCS1 v1.5 or PKCS1 PSS padding. PKCS v1.5 involves encoding to ASN.1 before padding.
3. The padded hash is finally RSA signed (i.e. modular exponentiation) and the signature is returned.

OpenSSL rsautl is very different. Here's what it does:

1. The input data is not hashed. It must be a small enough amount of data such that it can be padded and signed. PKCS v1.5 padding is always used. The data is not ASN.1 encoded before padding.
2. The PKCS v1.5 padded data is RSA signed and the signature is returned.

Download Chilkat RSA ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)



set pkey = CreateObject("Chilkat.PrivateKey")

'  Load the private key from an RSA PEM file:
success = pkey.LoadPemFile("private.pem")
If (success <> 1) Then
    MsgBox pkey.LastErrorText
    WScript.Quit
End If

'  Get the private key in XML format:
pkeyXml = pkey.GetXml()

set rsa = CreateObject("Chilkat.Rsa")

'  Any string argument automatically begins the 30-day trial.
success = rsa.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "RSA component unlock failed"
    WScript.Quit
End If

'  Import the private key into the RSA component:
success = rsa.ImportPrivateKey(pkeyXml)
If (success <> 1) Then
    MsgBox rsa.LastErrorText
    WScript.Quit
End If

'  This example will sign a string, and receive the signature
'  in a hex-encoded string.  Therefore, set the encoding mode
'  to "hex":
rsa.EncodingMode = "hex"

strData = "secret"

'  Create an OpenSSL style signature:
hexSig = rsa.OpenSslSignStringENC(strData)

outFile.WriteLine(hexSig)

'  Recover the data using the corresponding public key:
set pubkey = CreateObject("Chilkat.PublicKey")

'  Load the public key from a PEM file:
success = pubkey.LoadOpenSslPemFile("public.pem")
If (success <> 1) Then
    MsgBox pubkey.LastErrorText
    WScript.Quit
End If

'  Get the public key in XML format:
pubkeyXml = pubkey.GetXml()

set rsa2 = CreateObject("Chilkat.Rsa")

'  Import the public key into the RSA component:
success = rsa2.ImportPublicKey(pubkeyXml)
If (success <> 1) Then
    MsgBox rsa2.LastErrorText
    WScript.Quit
End If

rsa2.EncodingMode = "hex"

'  Recover the original data.

originalData = rsa2.OpenSslVerifyStringENC(hexSig)

outFile.WriteLine(originalData)
outFile.Close