About RSA Public/Private Keys

Download Chilkat RSA ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set cert = CreateObject("Chilkat.Cert")

'  Load a digital certificate.
success = cert.LoadFromFile("digitalCert.cer")
If (success <> 1) Then
    MsgBox cert.LastErrorText
    WScript.Quit
End If

'  A .cer file does not contain the private key.  It should contain
'  the public key...
' pubKey is a Chilkat.PublicKey
Set pubKey = cert.ExportPublicKey()

'  Let's have a look at it (in XML format).
outFile.WriteLine("Public Key from Certificate:")
outFile.WriteLine(pubKey.GetXml())

'  An RSA public key consists of a modulus and exponent.

'  An RSA private key includes both the modulus and exponent,
'  as well as other "big" numbers: P, Q, D, etc.

'  Let's load an RSA private key from a DER-encoded file:
set privKey = CreateObject("Chilkat.PrivateKey")

success = privKey.LoadRsaDerFile("PrivateKey.key")
If (success <> 1) Then
    MsgBox privKey.LastErrorText
    WScript.Quit
End If

'  If this private key is the matching half to the public key from
'  the certificate, then the modulus and exponent should
'  be identical.  (Thus, a "private key" really contains both the public part as well as the private parts...).
outFile.WriteLine("Private Key from DER:")
outFile.WriteLine(privKey.GetXml())

set rsa = CreateObject("Chilkat.Rsa")
success = rsa.UnlockComponent("Anything for 30-day trial.")
If (success <> 1) Then
    MsgBox rsa.LastErrorText
    WScript.Quit
End If

'  You now realize that the private key really contains both
'  private and public parts.  Therefore, we may import the private
'  key and the choose to use either the public or private in our
'  encrypt/decrypt operations:
privKeyXml = privKey.GetXml()
success = rsa.ImportPrivateKey(privKeyXml)
If (success <> 1) Then
    MsgBox rsa.LastErrorText
    WScript.Quit
End If


outFile.Close