Generate RSA Key and Sign a String

Demonstrates how to generate a new RSA public/private key pair and use it to generate a signature for a string. The (binary) digital signature is returned as a hexidecimalized string.

Download 32-bit Chilkat RSA ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set rsa = CreateObject("Chilkat.Rsa")

'  Any string argument automatically begins the 30-day trial.
success = rsa.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "RSA component unlock failed"
    WScript.Quit
End If

'  Generate a 1024-bit RSA key pair.
rsa.GenerateKey 1024

'  This example will sign a string, and receive the signature
'  in a hex-encoded string.  Therefore, set the encoding mode
'  to "hex":
rsa.EncodingMode = "hex"

'  If some other non-Chilkat application or web service is going to be verifying
'  the signature, it is important to match the byte-ordering.
'  The LittleEndian property may be set to 1
'  for little-endian byte ordering,
'  or 0  for big-endian byte ordering.
'  Microsoft apps typically use little-endian, while
'  OpenSSL and other services (such as Amazon CloudFront)
'  use big-endian.
rsa.LittleEndian = 0

strData = "This is the string to be signed."

'  Sign the string using the  md5 hash algorithm.
'  Other valid choices are "md2", "sha256", "sha384",
'  "sha512", and "sha-1".
hexSig = rsa.SignStringENC(strData,"md5")

outFile.WriteLine(hexSig)
outFile.WriteLine(rsa.LastErrorText)

'  Now verify the signature:
success = rsa.VerifyStringENC(strData,"md5",hexSig)
If (success = 1) Then
    MsgBox "Signature verified!"
Else
    outFile.WriteLine(rsa.LastErrorText)
End If

'  Try it with an invalid signature:
success = rsa.VerifyStringENC(strData,"md5","not a valid sig")
If (success = 1) Then
    MsgBox "Signature verified!"
Else
    outFile.WriteLine(rsa.LastErrorText)
End If

'  Try it with invalid data:
success = rsa.VerifyStringENC("Not the original data","md5",hexSig)
If (success = 1) Then
    MsgBox "Signature verified!"
Else
    outFile.WriteLine(rsa.LastErrorText)
End If

'  Try it with the wrong hash algorithm:
success = rsa.VerifyStringENC(strData,"sha-1",hexSig)
If (success = 1) Then
    MsgBox "Signature verified!"
Else
    outFile.WriteLine(rsa.LastErrorText)
End If

outFile.Close