RSA Encrypt and Decrypt Strings

VBScript sample code to RSA public-key encrypt and decrypt strings using public and private keys.

Download Chilkat RSA Public-Key Encryption ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set rsa = CreateObject("Chilkat.Rsa")

success = rsa.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox "RSA component unlock failed"
    WScript.Quit
End If

'  This example also generates the public and private
'  keys to be used in the RSA encryption.
'  Normally, you would generate a key pair once,
'  and distribute the public key to your partner.
'  Anything encrypted with the public key can be
'  decrypted with the private key.  The reverse is
'  also true: anything encrypted using the private
'  key can be decrypted using the public key.

'  Generate a 1024-bit key.  Chilkat RSA supports
'  key sizes ranging from 512 bits to 16384 bits.
success = rsa.GenerateKey(1024)
If (success <> 1) Then
    MsgBox rsa.LastErrorText
    WScript.Quit
End If

'  Keys are exported in XML format:
publicKey = rsa.ExportPublicKey()
privateKey = rsa.ExportPrivateKey()

plainText = "Encrypting and decrypting should be easy!"

'  Start with a new RSA object to demonstrate that all we
'  need are the keys previously exported:
set rsaEncryptor = CreateObject("Chilkat.Rsa")

'  Encrypted output is always binary.  In this case, we want
'  to encode the encrypted bytes in a printable string.
'  Our choices are "hex", "base64", "url", "quoted-printable".
rsaEncryptor.EncodingMode = "hex"

'  We'll encrypt with the public key and decrypt with the private
'  key.  It's also possible to do the reverse.
rsaEncryptor.ImportPublicKey publicKey

usePrivateKey = 0
encryptedStr = rsaEncryptor.EncryptStringENC(plainText,usePrivateKey)
outFile.WriteLine(encryptedStr)

'  Now decrypt:
set rsaDecryptor = CreateObject("Chilkat.Rsa")

rsaDecryptor.EncodingMode = "hex"
rsaDecryptor.ImportPrivateKey privateKey

usePrivateKey = 1
decryptedStr = rsaDecryptor.DecryptStringENC(encryptedStr,usePrivateKey)

outFile.WriteLine(decryptedStr)
outFile.Close