VBScript

HTTP Download to Stream

See more REST Examples

Demonstrates how to stream the response body directly to a stream, which in this case is to a file stream. VBScript

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set rest = CreateObject("Chilkat.Rest")

' The URL we want to download is: 
' https://github.com/chilkatsoft/OAuth2-CSharp-Desktop/archive/master.zip
set url = CreateObject("Chilkat.Url")
success = url.ParseUrl("https://github.com/chilkatsoft/OAuth2-CSharp-Desktop/archive/master.zip")

' Connect to the web server
bAutoReconnect = 1
success = rest.Connect(url.Host,url.Port,url.Ssl,bAutoReconnect)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

success = rest.SendReqNoBody("GET",url.Path)
If (success <> 1) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

' Read the response header.
responseStatusCode = rest.ReadResponseHeader()
If (responseStatusCode < 0) Then
    outFile.WriteLine(rest.LastErrorText)
    WScript.Quit
End If

outFile.WriteLine("Response status code = " & responseStatusCode)

' We expect a 200 response status if the file data is coming.
' Otherwise, we'll get a string response body with an error message(or no response body).
If (responseStatusCode = 200) Then

    set bodyStream = CreateObject("Chilkat.Stream")

    ' The stream's sink will be a file.
    bodyStream.SinkFile = "qa_output/OAuth2-CSharp-Desktop/archive/master.zip"

    ' Read the response body to the stream.  Given that we've
    ' set the stream's sink to a file, it will stream directly
    ' to the file.
    success = rest.ReadRespBodyStream(bodyStream,1)
    If (success <> 1) Then
        outFile.WriteLine(rest.LastErrorText)
        WScript.Quit
    End If

    outFile.WriteLine("Successfully downloaded the file.")

Else
    errResponse = rest.ReadRespBodyString()
    If (rest.LastMethodSuccess <> 1) Then
        outFile.WriteLine(rest.LastErrorText)
    Else
        outFile.WriteLine(errResponse)
    End If

End If


outFile.Close