Reading Unread POP3 Email

Download Chilkat Email ActiveX

The POP3 protocol does not provide the ability to ask the server which emails are "unread". Furthermore, a pure POP3 server does not even keep this information. Some servers, such as Exchange Server, expose both POP3 and IMAP interfaces. In these cases, information about read/unread status exists on the server, but it is only available via the IMAP protocol. Email clients such as Outlook and Thunderbird keep read/unread information on the client computer. This example demonstrates how UIDLs can be saved to track and read "unread" email.

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

'  The mailman object is used for receiving (POP3)
'  and sending (SMTP) email.
set mailman = CreateObject("Chilkat.MailMan2")

'  Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    WScript.Quit
End If

'  Set the POP3 server's hostname
mailman.MailHost = "mail.chilkatsoft.com"

'  Set the POP3 login/password.
mailman.PopUsername = "***"
mailman.PopPassword = "***"

'  We're keeping a list of already-seen UIDLs in a text file:
'  If this is the first time you're running this example,
'  create an empty text file named "seenUidls.txt"
set saSeenUidls = CreateObject("Chilkat.CkStringArray")
success = saSeenUidls.LoadFromFile("seenUidls.txt")
If (success <> 1) Then
    MsgBox "failed to load seenUidls.txt"
    WScript.Quit
End If

'  Get the complete list of UIDLs on the mail server.

Set saUidls = mailman.GetUidls()

If (saUidls Is Nothing ) Then
    MsgBox mailman.LastErrorText
    WScript.Quit
End If

'  We don't have set operators (yet) on the StringArray object,
'  so create a new string array object (it's an object, not an actual array)
'  and add the UIDLs from saUidls that aren't already seen.
set saUnseenUidls = CreateObject("Chilkat.CkStringArray")

n = saUidls.Count
For i = 0 To n - 1
    If (saSeenUidls.Contains(saUidls.GetString(i)) <> 1) Then
        saUnseenUidls.Append saUidls.GetString(i)
    End If

Next

If (saUnseenUidls.Count = 0) Then
    MsgBox "No unseen emails!"

    WScript.Quit
End If

'  Download in full the unseen emails:

Set bundle = mailman.FetchMultiple(saUnseenUidls)
If (bundle Is Nothing ) Then
    MsgBox mailman.LastErrorText

    WScript.Quit
End If

For i = 0 To bundle.MessageCount - 1
    Set email = bundle.GetEmail(i)
    outFile.WriteLine(email.From)
    outFile.WriteLine(email.Subject)
    outFile.WriteLine("----")

Next

'  We've seen all the emails, save saUidls to "seenUidls.txt"
saUidls.SaveToFile "seenUidls.txt"


outFile.Close