Download and Save Email Attachments (POP3)

Downloads emails from a POP3 mailbox and saves all attachments.

Download Chilkat Email ActiveX for POP3 / SMTP

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

'  The mailman object is used for receiving (POP3)
'  and sending (SMTP) email.
set mailman = CreateObject("Chilkat.MailMan2")

'  Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    WScript.Quit
End If

'  Set the POP3 server's hostname
mailman.MailHost = "mail.chilkatsoft.com"

'  Set the POP3 login/password.
mailman.PopUsername = "***"
mailman.PopPassword = "***"

'  Copy the all email from the user's POP3 mailbox
'  into a bundle object.  The email remains on the server.
Set bundle = mailman.CopyMail()

If (bundle Is Nothing ) Then
    MsgBox mailman.LastErrorText
    WScript.Quit
End If

dirPath = "c:/myAttachments"

For i = 0 To bundle.MessageCount - 1
    Set email = bundle.GetEmail(i)

    '  You may save all the attachments to the specified directory
    '  by calling SaveAllAttachments.
    '  The SaveAllAttachments method will automatically create the directory
    '  if it does not already exist.
    success = email.SaveAllAttachments(dirPath)
    If (success <> 1) Then
        MsgBox email.LastErrorText
        WScript.Quit
    End If

    '  The OverwriteExisting property controls whether already-existing files
    '  are automatically overwritten.  By default, it is set to 1 so that existing
    '  files will be overwritten.

    '  Setting OverwriteExisting = 0 will cause the attachment-saving methods to generate
    '  unique filenames if a file with the same name already exists.  The actual filename(s)
    '  saved will be present by calling GetAttachmentFilename for each attachment *after*
    '  saving.
    '  For example...
    email.OverwriteExisting = 0
    success = email.SaveAllAttachments(dirPath)
    If (success <> 1) Then
        MsgBox email.LastErrorText
        WScript.Quit
    End If

    n = email.NumAttachments

    For j = 0 To n - 1
        '  If the attachment filename was changed to prevent overwriting,
        '  GetAttachmentFilename will return the new filename.
        outFile.WriteLine(email.GetAttachmentFilename(j))
    Next

    '  You may also save individual attachments:
    For j = 0 To n - 1

        outFile.WriteLine("Original Filename: " _
             & email.GetAttachmentFilename(j))
        success = email.SaveAttachedFile(j,dirPath)
        If (success <> 1) Then
            MsgBox email.LastErrorText
            WScript.Quit
        End If

        '  If OverwriteExisting = 1, the saved filename will always equal the original filename,
        '  unless there are characters present in the filename that are not allowed by Windows,
        '  such as * ? < > | etc.  In those cases the illegal characters are either removed or replaced
        '  with underscore characters to allow the file to be saved.
        outFile.WriteLine("Saved Filename: " _
             & email.GetAttachmentFilename(j))
    Next

Next


outFile.Close