Process Large POP3 Mailbox

Download Chilkat Email ActiveX

Demonstrates how to read email from a mailbox that may contain a large number of emails (on the order of thousands of emails or more).

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

'  The mailman object is used for receiving (POP3)
'  and sending (SMTP) email.
set mailman = CreateObject("Chilkat.MailMan2")

'  Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    WScript.Quit
End If

'  Set the POP3 server's hostname
mailman.MailHost = "mail.chilkatsoft.com"

'  Set the POP3 login/password.
mailman.PopUsername = "myLogin"
mailman.PopPassword = "myPassword"

'  First, get the list of UIDLs for all emails in the mailbox.

Set sa = mailman.GetUidls()

numEmails = sa.Count

'  Download the emails in chunks of 10 emails each.
chunkBeginIdx = 0
chunkEndIdx = 9
If (chunkEndIdx >= numEmails) Then
    chunkEndIdx = numEmails - 1
End If

set saChunk = CreateObject("Chilkat.CkStringArray")
Do While (chunkEndIdx < (numEmails - 1))

    '  Build a chunk of 10 UIDLs.
    saChunk.Clear 
    For i = chunkBeginIdx To chunkEndIdx
        saChunk.Append sa.GetString(i)
    Next

    '  Display the UIDLs in this chunk...

    chunkStr = saChunk.SaveToText()
    outFile.WriteLine(chunkStr)
    outFile.WriteLine("----" & vbCrLf)

    '  Download this chunk of email from the POP3 server.

    Set bundle = mailman.FetchMultiple(saChunk)
    If (bundle Is Nothing ) Then
        MsgBox mailman.LastErrorText
        WScript.Quit
    End If

    '  Process the bundle...
    '  (your application's processing code goes here...)

    '  Get the next chunk...
    chunkBeginIdx = chunkBeginIdx + 10
    If (chunkBeginIdx >= numEmails) Then
        Exit Do
    End If

    chunkEndIdx = chunkEndIdx + 10
    If (chunkEndIdx >= numEmails) Then
        chunkEndIdx = numEmails - 1
    End If

Loop


outFile.Close