Read Email from a POP3 Server and Re-Send

Read email from a POP3 server and re-send those emails matching a specific criteria.

Download Chilkat Email ActiveX for POP3 / SMTP

'  The mailman object is used for receiving (POP3)
'  and sending (SMTP) email.
set mailman = CreateObject("Chilkat.MailMan2")

'  Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    WScript.Quit
End If

'  Set the SMTP server.
mailman.SmtpHost = "smtp.comcast.net"

'  Depending on your SMTP server, you may need authentication:
'  mailman.SmtpUsername = "myLogin";
'  mailman.SmtpPassword = "myPassword";

'  Set the POP3 server's hostname
mailman.MailHost = "mail.chilkatsoft.com"

'  Set the POP3 login/password.
mailman.PopUsername = "matt@chilkatsoft.com"
mailman.PopPassword = "****"

'  Copy the all email from the user's POP3 mailbox
'  into a bundle object.  The email remains on the server.
'  Call TransferMail instead to download and remove the email
'  from the server.
Set bundle = mailman.CopyMail()

If (bundle Is Nothing ) Then
    MsgBox mailman.LastErrorText
    WScript.Quit
End If

For i = 0 To bundle.MessageCount - 1
    Set email = bundle.GetEmail(i)

    '  
If InStr(email.Subject,"Test HTML") > 0 Then
    '  Clear the recipients from the existing email:
    email.ClearTo 
    email.ClearCC 

    '  Add a new recipient.  Call AddTo or AddCC
    '  once for each recipient:
    email.AddTo "Chilkat Support","support@chilkatsoft.com"

    '  Resend the email (including attachments)
    success = mailman.SendEmail(email)
    If (success <> 1) Then
        MsgBox mailman.LastErrorText
        WScript.Quit
    End If

    '  
End If

Next