Display Email Attachment Filenames

Read a POP3 mailbox and display the attachment filenames for all emails.

Download Chilkat Email ActiveX for POP3 / SMTP

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

'  The mailman object is used for receiving (POP3)
'  and sending (SMTP) email.
set mailman = CreateObject("Chilkat.MailMan2")

'  Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    WScript.Quit
End If

'  Set the POP3 server's hostname
mailman.MailHost = "mail.chilkatsoft.com"

'  Set the POP3 login/password.
mailman.PopUsername = "matt@chilkatsoft.com"
mailman.PopPassword = "****"

'  Copy the all email from the user's POP3 mailbox
'  into a bundle object.  The email remains on the server.
Set bundle = mailman.CopyMail()

If (bundle Is Nothing ) Then
    MsgBox mailman.LastErrorText
    WScript.Quit
End If

For i = 0 To bundle.MessageCount - 1
    Set email = bundle.GetEmail(i)
    numAttach = email.NumAttachments
    If (numAttach > 0) Then
        For j = 0 To numAttach - 1
            outFile.WriteLine(email.GetAttachmentFilename(j))
        Next
    End If

Next


outFile.Close