Delete Individual Emails from POP3 Mailbox

Demonstrates how to delete individual emails from a POP3 mailbox.

Download Chilkat Email ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

'  The mailman object is used for receiving (POP3)
'  and sending (SMTP) email.
set mailman = CreateObject("Chilkat.MailMan2")

'  Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox "Component unlock failed"
    WScript.Quit
End If

'  Set the POP3 server's hostname
mailman.MailHost = "mail.chilkatsoft.com"

'  Set the POP3 login/password.
mailman.PopUsername = "myLogin"
mailman.PopPassword = "myPassword"

'  Set the ImmediateDelete property = 0
'  When the DeleteEmail method is called, the POP3 session
'  will remain open and the emails will be deleted all at once
'  when the session closes.
mailman.ImmediateDelete = 0

'  Download email headers.
' bundle is a Chilkat.EmailBundle2
Set bundle = mailman.GetAllHeaders(1)

If (bundle Is Nothing ) Then
    MsgBox mailman.LastErrorText
    WScript.Quit
End If

For i = 0 To bundle.MessageCount - 1
    ' email is a Chilkat.Email2
    Set email = bundle.GetEmail(i)

    outFile.WriteLine(email.From & vbCrLf)
    outFile.WriteLine(email.Subject & vbCrLf)

    '  If you decide the email is to be deleted, call DeleteEmail.
    '  This marks the email for deletion on the POP3 server.
    success = mailman.DeleteEmail(email)
    If (success <> 1) Then
        MsgBox mailman.LastErrorText
        WScript.Quit
    End If

Next

'  Make sure the POP3 session is ended to finalize the deletes.
success = mailman.Pop3EndSession()
If (success <> 1) Then
    MsgBox mailman.LastErrorText
End If

MsgBox "Success!"
outFile.Close