PKCS7 SignedData Detached Signature

How to create a PKCS7 detached signature. The resulting PKCS7 structure is encoded to a printable string using hex or base64 encoding. The data being signed is not included in the PKCS#7 structure.

Download Chilkat Crypt ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set crypt = CreateObject("Chilkat.Crypt2")

'  Any string argument automatically begins the 30-day trial.
success = crypt.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Crypt component unlock failed"
    WScript.Quit
End If

set cert = CreateObject("Chilkat.Cert")
success = cert.LoadByCommonName("Chilkat Software")
If (success <> 1) Then
    MsgBox cert.LastErrorText
    WScript.Quit
End If

'  Make sure this certificate has a private key available:

bHasPrivateKey = cert.HasPrivateKey()
If (bHasPrivateKey <> 1) Then
    MsgBox "No private key available for signing."
    WScript.Quit
End If

'  Tell the encryption component to use this cert.
crypt.SetSigningCert cert

strData = "This is the data to be signed."

'  Indicate that the PKCS7 signature should be returned
'  as a base64 encoded string:
crypt.EncodingMode = "base64"

'  The EncodingMode may be set to other values such as
'  "hex", "url", "quoted-printable", etc.

strSignature = crypt.SignStringENC(strData)

outFile.WriteLine(strSignature)

'  Now verify the signature against the original data.

'  Tell the component what certificate to use for verification.
crypt.SetVerifyCert cert

success = crypt.VerifyStringENC(strData,strSignature)
If (success = 1) Then
    MsgBox "digital signature verified"
Else
    MsgBox "digital signature invalid"
End If

'  Try it with incorrect data:
success = crypt.VerifyStringENC("This is not the signed data",strSignature)
If (success = 1) Then
    MsgBox "digital signature verified"
Else
    MsgBox "digital signature invalid"
End If

outFile.Close