PFX to PEM (Certificate and Private Key Files)

Export a certificate and private key from a PFX to a pair of PEM files.

set certStore = CreateObject("Chilkat.CertStore")

'  Load the PFX file into a certificate store object

password = "myPassword"
success = certStore.LoadPfxFile("chilkat.pfx",password)
If (success <> 1) Then
    MsgBox certStore.LastErrorText
    WScript.Quit
End If

'  Find the cert to be exported by the subject:

' cert is a Chilkat.Cert
Set cert = certStore.FindCertBySubject("Chilkat Software, Inc.")
If (cert Is Nothing ) Then
    MsgBox "Certificate not found."
    WScript.Quit
End If

'  Does this cert have a private key?
If (cert.HasPrivateKey() = 1) Then

    '  Get the private key.

    ' pvkey is a Chilkat.PrivateKey
    Set pvkey = cert.ExportPrivateKey()

    '   Export the private key to a PEM file:
    success = pvkey.SaveRsaPemFile("chilkat_pkey.pem")
    If (success <> 1) Then
        MsgBox pvkey.LastErrorText
        WScript.Quit
    End If

End If

'  Save the cert to a PEM file:
success = cert.ExportCertPemFile("chilkat_cert.pem")
If (success <> 1) Then
    MsgBox cert.LastErrorText
    WScript.Quit
End If