Submit Credit Card Transaction to PayPal

Submits a credit card transaction to PayPal. The response parameters are displayed for both success and error responses.

This example communicates directly with PayPal's Payflow servers via HTTPS.

Download Chilkat HTTP ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set req = CreateObject("Chilkat.HttpRequest")
set http = CreateObject("Chilkat.Http")

'  Any string unlocks the component for the 1st 30-days.
success = http.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox http.LastErrorText
    WScript.Quit
End If

'  These are obviously not real credentials...
username = "seller_1999999893_biz_api1.chilkatsoft.com"
password = "1992299958"
signature = "ALgNZbbbUgjlBaRnvTKJg8-C6AGpAepaaa1rysDXe1OnF7pJcaccccmN"
version = "3.2"

'  The PayPal NVP sandbox server for API Signature Security is:
'  https://api-3t.sandbox.paypal.com/nvp

'  Build an HTTPS POST Request:
req.UsePost 
req.Path = "/nvp"

'  The content-type should be text/namevalue
req.AddHeader "content-type","text/namevalue"

req.AddParam "METHOD","doDirectPayment"
req.AddParam "PAYMENTACTION","Sale"
req.AddParam "AMT","1.00"
req.AddParam "IPADDRESS","37.174.133.150"
'  Visa, Discover, Mastercard, or Amex
req.AddParam "CREDITCARDTYPE","Visa"
req.AddParam "ACCT","4397920706128982"
'  expiration date should be formatted MMYYYY
req.AddParam "EXPDATE","022010"
req.AddParam "CVV2","382"
req.AddParam "FIRSTNAME","Test"
req.AddParam "LASTNAME","User"
req.AddParam "STREET","1 Main St"
req.AddParam "CITY","San Jose"
req.AddParam "STATE","CA"
req.AddParam "ZIP","95131"
req.AddParam "COUNTRYCODE","US"
req.AddParam "CURRENCYCODE","USD"

'  Credentials and version:
req.AddParam "VERSION",version
req.AddParam "USER",username
req.AddParam "PWD",password
req.AddParam "SIGNATURE",signature

'  Send the HTTPS POST and get the response.  Note: This is a blocking call.
'  The method does not return until the full HTTP response is received.

domain = "api-3t.sandbox.paypal.com"
port = 443
ssl = 1

'  120-second non-activity timeout.
http.ReadTimeout = 15

Set resp = http.SynchronousRequest(domain,port,ssl,req)
If (resp Is Nothing ) Then
    outFile.WriteLine(http.LastErrorText)
Else

    '  The response body is in NVP format -- which is nothing more than URL-encoded name/value pairs.
    '  One easy way to parse it is to use the HttpRequest
    '  object in an unorthodox way.
    '  We'll create a fake URL that contains the name/value pairs
    '  found in the body of the response.
    '  Then we'll load it into a temporary HTTP request object.
    '  The HTTP request object does the parsing for us, and we
    '  can look at the params...

    fakeUrl = "http://www.test.com/abc.asp?" & resp.BodyStr

    '  We're only using this request object to parse the NVP-formatted response body.
    set req2 = CreateObject("Chilkat.HttpRequest")
    req2.SetFromUrl fakeUrl

    '  The ACK param can have these values:
    '  Successful responses:
    '  Success
    '  SuccessWithWarning
    '  Error responses:
    '  Failure
    '  FailureWithWarning
    '  Warning
    outFile.WriteLine("ACK: " & req2.GetParam("ACK"))

    '  Assuming success, we'll have these params:
    outFile.WriteLine("AMT: " & req2.GetParam("AMT"))
    outFile.WriteLine("CURRENCYCODE: " & req2.GetParam("CURRENCYCODE"))
    outFile.WriteLine("AVSCODE: " & req2.GetParam("AVSCODE"))
    outFile.WriteLine("CVV2MATCH: " & req2.GetParam("CVV2MATCH"))
    outFile.WriteLine("TRANSACTIONID: " & req2.GetParam("TRANSACTIONID"))
    outFile.WriteLine("TIMESTAMP: " & req2.GetParam("TIMESTAMP"))
    outFile.WriteLine("CORRELATIONID: " & req2.GetParam("CORRELATIONID"))
    outFile.WriteLine("VERSION: " & req2.GetParam("VERSION"))
    outFile.WriteLine("BUILD: " & req2.GetParam("BUILD"))

    '  On failure, some of the above params will be set, but these
    '  params will also be present:
    outFile.WriteLine("L_ERRORCODE0: " & req2.GetParam("L_ERRORCODE0"))
    outFile.WriteLine("L_SHORTMESSAGE0: " & req2.GetParam("L_SHORTMESSAGE0"))
    outFile.WriteLine("L_LONGMESSAGE0: " & req2.GetParam("L_LONGMESSAGE0"))
    outFile.WriteLine("L_SEVERITYCODE0: " & req2.GetParam("L_SEVERITYCODE0"))

End If

outFile.Close