S/MIME Signed Message

Download Chilkat MIME ActiveX

Create an S/MIME signed (PKCS7) message.

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set mime = CreateObject("Chilkat.Mime")

success = mime.UnlockComponent("Anything for 30-day trial.")
If (success = 0) Then
    MsgBox mime.LastErrorText
    WScript.Quit
End If

mime.AddHeaderField "Subject","This is a test"
mime.AddHeaderField "Abc","123"

mime.SetBodyFromPlainText "This is the body"

set cert = CreateObject("Chilkat.Cert")
'  Load a certificate that has already been installed (from a .pfx)
'  on the computer:
success = cert.LoadByEmailAddress("thawte@chilkatsoft.com")
If (success = 0) Then
    MsgBox cert.LastErrorText
    WScript.Quit
End If

'  Convert to a signed message.
success = mime.ConvertToSigned(cert)
If (success = 0) Then
    MsgBox mime.LastErrorText
    WScript.Quit
End If

'  Display the signed MIME:
outFile.WriteLine(mime.GetMime())

outFile.WriteLine("----")

'  Unwrap to restore the original MIME.
success = mime.UnwrapSecurity()
If (success = 0) Then
    MsgBox mime.LastErrorText
    WScript.Quit
End If

'  Display the restored (unsigned) MIME:
outFile.WriteLine(mime.GetMime())

outFile.Close