Create Multipart/Alternative MIME

Download Chilkat MIME ActiveX

Create a simple multipart/alternative MIME message.

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)


set mime = CreateObject("Chilkat.Mime")

success = mime.UnlockComponent("Anything for 30-day trial")
If (success = 0) Then
    MsgBox "Failed to unlock"
    WScript.Quit
End If

'  Make this a multipart/alternative MIME message:
mime.NewMultipartAlternative 

'  Create a plain-text part and add it to the multipart/alternative MIME.
set ptMime = CreateObject("Chilkat.Mime")
ptMime.SetBodyFromPlainText "This is the plain-text body"
mime.AppendPart ptMime

'  Now do the same for HTML:
set htMime = CreateObject("Chilkat.Mime")
htMime.SetBodyFromHtml "<html><body>This is the HTML body</body></html>"
mime.AppendPart htMime

'  Show the full multipart/alternative MIME text which includes both parts:
outFile.WriteLine(mime.GetMime())

'  Need to change the boundary string?
mime.Boundary = "__NewBoundaryString__123"

'  Need to change the charset?
' ptMime is a Chilkat.Mime
Set ptMime = mime.GetPart(0)
ptMime.Charset = "utf-8"
' htMime is a Chilkat.Mime
Set htMime = mime.GetPart(1)
htMime.Charset = "utf-8"

'  Need to change the encoding?
htMime.Encoding = "base64"

'  Now show the MIME again:
outFile.WriteLine("---- After Changes ----")
outFile.WriteLine(mime.GetMime())

outFile.Close

Mail Component · XML Parser