Get the text body content of a MIME part.

Explains and demonstrates the GetBodyEncoded and GetBodyDecoded methods. This example uses the MIME test data located at http://www.chilkatsoft.com/testData/sampleMime1.txt

The sampleMime1.txt contains:

Content-Type: multipart/mixed;
 boundary="------------070404010201060604000708"

This is a multi-part message in MIME format.

--------------070404010201060604000708
Content-Transfer-Encoding: quoted-printable
Content-Type: text/plain; charset="utf-8"

Falsches =C3=9Cben von Xylophonmusik qu=C3=A4lt jeden gr=C3=B6=C3=9Feren Zwe=
rg.
--------------070404010201060604000708
Content-Transfer-Encoding: base64
Content-Type: text/plain; charset="utf-8"

RmFsc2NoZXMgw5xiZW4gdm9uIFh5bG9waG9ubXVzaWsgcXXDpGx0IGplZGVuIGdyw7bDn2VyZW4g
Wndlcmcu

--------------070404010201060604000708
Content-Transfer-Encoding: 8bit
Content-Type: text/plain; charset="iso-8859-1"

Falsches Üben von Xylophonmusik quält jeden größeren Zwerg.
--------------070404010201060604000708--

Download Chilkat MIME ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set mime = CreateObject("Chilkat.Mime")

success = mime.UnlockComponent("Anything for 30-day trial.")
If (success = 0) Then
    outFile.WriteLine(mime.LastErrorText)
    WScript.Quit
End If

'  Load the sampleMime1.txt file into the MIME object.
'  (This file is available at http://www.chilkatsoft.com/testData/sampleMime1.txt )

success = mime.LoadMimeFile("sampleMime1.txt")
If (success = 0) Then
    outFile.WriteLine(mime.LastErrorText)
    WScript.Quit
End If

'  The sampleMime1.txt is a MIME document with a top-level
'  multipart/mixed containing 3 sub-parts, each of which has the
'  same body text but with different content-transfer-encodings and
'  using different character encodings (utf-8 and iso-8859-1).

'  Calling mime.GetBodyEncoded or mime.GetBodyDecoded on the
'  top-level multipart/mixed MIME object will return an empty string.
'  It is because the "body" of a multipart MIME object is always empty.
'  A multipart MIME object contains sub-parts (each a MIME object),
'  and it is only the leaf-objects that can have non-empty bodies.

'  Get GetBodyDecoded method returns the body text decoded
'  from whatever the content-transfer-encoding may be, and
'  converted from whatever charset encoding might be used.
'  In this case, calling GetBodyDecoded on each of the three
'  sub-parts will return the same string.
'  To demonstrate:

' part1 is a Chilkat.Mime
Set part1 = mime.GetPart(0)
outFile.WriteLine(part1.GetBodyDecoded())

' part2 is a Chilkat.Mime
Set part2 = mime.GetPart(1)
outFile.WriteLine(part2.GetBodyDecoded())

' part3 is a Chilkat.Mime
Set part3 = mime.GetPart(2)
outFile.WriteLine(part3.GetBodyDecoded())

'  The GetBodyEncoded method will NOT decode from
'  whatever content-transfer-encoding is used.  However, it will
'  convert from whatever internal character encoding
'  may be used to return a string appropriate for the calling
'  programming language (for example, in .NET or any language
'  using ActiveX, all strings are Unicode..)
outFile.WriteLine(part1.GetBodyEncoded())
outFile.WriteLine(part2.GetBodyEncoded())
outFile.WriteLine(part3.GetBodyEncoded())


outFile.Close