Convert HTML File to Email with Embedded Images

Converts an HTML file into an email with embedded images and sends. The HTML image may contain IMG tags with SRC attributes referencing images on the local filesystem or on the Web. The MHT component will gather all referenced images, style sheets, etc. regardless of whether they are located on the filesystem or the Web via an http or https URL.

Download Chilkat Email ActiveX for POP3 / SMTP

Download Chilkat MHT ActiveX

' The mailman object is used for receiving (POP3)
' and sending (SMTP) email.
set mailman = CreateObject("Chilkat.MailMan2")

' The MHT component can be used to convert an HTML page
' from a URL, file, or in-memory HTML into an email
' with embedded images and style sheets.
set mht = CreateObject("Chilkat.Mht")

' Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "MailMan component unlock failed"
    WScript.Quit
End If

success = mht.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Mht component unlock failed"
    WScript.Quit
End If

' There are two ways of embedding images in emails: with CIDs
' and without.  When using CIDs, the IMG SRC attributes use
' urls that begin with "CID:" and the corresponding image
' embedded within the email includes a Content-ID header field.
' When not using CIDs, the IMG SRC attribute can have a URL,
' path, etc. and the corresponding image embedded within
' the email has a matching Content-Location header field.

' When testing with GMail, if CIDs are used the email will
' be displayed with images blocked (by default) unless
' the user allows them to be displayed.  Without CIDs,
' the images are automatically displayed.

' When testing with Eudora, Mozilla Thunderbird, and Outlook Express,
' embedded images display correctly with our without CIDs.

' When testing with Yahoo! Mail, embedded images display OK.
' However, the Yahoo! Mail user has the option of blocking
' images.  If this is turned on, the CID images will still
' display correctly even though images are blocked.  Why?
' It's because when viewing the email there is no external
' HTTP request to fetch an image.  Therefore, a spammer
' cannot get an indication that you've read the email.
' However, if CIDs are not used, the images are blocked by
' any Yahoo! Mail user that has image blocking turned on --
' even though the images are embedded.

' I haven't tested Hotmail yet...
' Regardless, there is no perfect solution.  If CIDs are used,
' GMail users may block your embedded images, if CIDs are not
' used, Yahoo! Mail users may block your embedded images.

' I recommend setting using CIDs.  This is what Mozilla Thunderbird
' does by default, and it's the more clear an unambiguous way
' to indicate that images are indeed embedded.
mht.UseCids = 1

' Create an email from an HTML file.
Set email = mht.GetEmail("c:/temp/bonaireFishing.html")
If (email Is Nothing ) Then
    MsgBox mht.LastErrorText
    WScript.Quit
End If

email.Subject = "Test HTML email"

' This example is tested in:
' Outlook 2000, Eudora 7, Mozilla Thunderbird 1.5.0.9, Outlook Express 6, GMail, Yahoo Mail
email.AddTo "Chilkat Support","support@chilkatsoft.com"

' Note: Chilkat does not regularly check our GMail and Yahoo
' email accounts.  Please send support email to support@chilkatsoft.com
email.AddTo "Chilkat on Yahoo","chilkat_software@yahoo.com"
email.AddTo "Chilkat on GMail","chilkat.support@gmail.com"

email.From = "admin@chilkatsoft.com"

mailman.SmtpHost = "smtp.comcast.net"

success = mailman.SendEmail(email)
If (success <> 1) Then
    MsgBox mailman.LastErrorText
    WScript.Quit
End If

MsgBox "HTML Email Sent!"