Using Client Certificate w/ IMAP SSL

Demonstrates how to use a client-side certificate with an IMAP SSL connection. The SetSslClientCert method is called to specify a certificate to be used for the SSL connection.

Download Chilkat IMAP ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set imap = CreateObject("Chilkat.Imap")

'  Anything unlocks the component and begins a fully-functional 30-day trial.
success = imap.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  To use a secure SSL connection, set SSL and the port:
imap.Ssl = 1
'  The typical port for IMAP SSL is 993
imap.Port = 993

'  Load a certificate from a PFX file and use it.
'  Note: Other methods are available to load pre-installed
'  certificates from registry-based certificate stores.

'  Create an instance of a certificate store object, load a PFX file,
'  locate the certificate we need, and use it for signing.
'  (a PFX file may contain more than one certificate.)
set certStore = CreateObject("Chilkat.CertStore")
'  The 1st argument is the filename, the 2nd arg is the
'  PFX file's password:
success = certStore.LoadPfxFile("myCertWithPrivateKey.pfx","secret")
If (success <> 1) Then
    MsgBox certStore.LastErrorText
    WScript.Quit
End If

'  Find the certificate by the subject common name:

Set cert = certStore.FindCertBySubjectCN("Chilkat Software, Inc.")
If (cert Is Nothing ) Then
    MsgBox certStore.LastErrorText
    WScript.Quit
End If

'  If a PFX file is known to contain a single certificate,
'  you may load it directly into a Chilkat certificate object.
'  This snippet of source code shows how:
set cert2 = CreateObject("Chilkat.Cert")
'  The 1st argument is the filename, the 2nd arg is the
'  PFX file's password:
success = cert2.LoadPfxFile("tagtooga_secret.pfx","secret")
If (success <> 1) Then
    MsgBox cert.LastErrorText
    WScript.Quit
End If

'  Use the cert:
imap.SetSslClientCert cert

'  Connect to an IMAP server.
success = imap.Connect("mail.chilkatsoft.com")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Login
success = imap.Login("myLogin","myPassword")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  We can choose to fetch UIDs or sequence numbers.
fetchUids = 1
'  Get the message IDs of all the emails in the mailbox
Set messageSet = imap.Search("ALL",fetchUids)
If (messageSet Is Nothing ) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Fetch the emails into a bundle object:

Set bundle = imap.FetchBundle(messageSet)
If (bundle Is Nothing ) Then

    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Loop over the bundle and display the FROM and SUBJECT of each.

For i = 0 To bundle.MessageCount - 1

    Set email = bundle.GetEmail(i)
    outFile.WriteLine(email.From)
    outFile.WriteLine(email.Subject)
    outFile.WriteLine("--")

Next

'  Disconnect from the IMAP server.
imap.Disconnect 


outFile.Close