IMAP using SOCKS5, SOCKS4 Proxy

Download Chilkat Email ActiveX

Demonstrates how to connect to an IMAP server through a SOCKS5 or SOCKS4 proxy.

Download 32-bit Chilkat IMAP ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set imap = CreateObject("Chilkat.Imap")

'  Anything unlocks the component and begins a fully-functional 30-day trial.
success = imap.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  To use a SOCKS4 or SOCKS5 proxy, simply set the following
'  properties prior to connecting with the IMAP server:
'  The SOCKS hostname may be a domain name or
'  IP address:
imap.SocksHostname = "www.mysocksproxyserver.com"
imap.SocksPort = 1080
imap.SocksUsername = "myProxyLogin"
imap.SocksPassword = "myProxyPassword"
'  Set the SOCKS version to 4 or 5 based on the version
'  of the SOCKS proxy server:
imap.SocksVersion = 5
'  Note: SOCKS4 servers only support usernames without passwords.
'  SOCKS5 servers support full login/password authentication.

'  Connect to an IMAP server through the SOCKS proxy.
success = imap.Connect("mail.chilkatsoft.com")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Login
success = imap.Login("myLogin","myPassword")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  We can choose to fetch UIDs or sequence numbers.
fetchUids = 1
'  Get the message IDs of all the emails in the mailbox
' messageSet is a Chilkat.MessageSet
Set messageSet = imap.Search("ALL",fetchUids)
If (messageSet Is Nothing ) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Fetch the emails into a bundle object:

' bundle is a Chilkat.EmailBundle2
Set bundle = imap.FetchBundle(messageSet)
If (bundle Is Nothing ) Then

    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Loop over the bundle and display the FROM and SUBJECT of each.

For i = 0 To bundle.MessageCount - 1

    ' email is a Chilkat.Email2
    Set email = bundle.GetEmail(i)
    outFile.WriteLine(email.From)
    outFile.WriteLine(email.Subject)
    outFile.WriteLine("--")

Next

'  Disconnect from the IMAP server.
imap.Disconnect 


outFile.Close