Read S/MIME Encrypted Email

Read S/MIME encrypted email.

Download Chilkat IMAP ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set imap = CreateObject("Chilkat.Imap")

'  Anything unlocks the component and begins a fully-functional 30-day trial.
success = imap.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Connect to an IMAP server.
success = imap.Connect("mail.chilkatsoft.com")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Login
success = imap.Login("myLogin","myPassword")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  The AutoUnwrapSecurity method controls whether signed/encrypted emails are automatically
'  decrypted and/or verified.

'  When set to 1, which is the default, security envelopes are automatically "unwrapped"
'  when a message is retrieved from the server. Signed emails are automatically verified, and
'  encrypted emails are automatically decrypted, restoring the email to the original state before
'  signing and/or encrypting. Information about the signing and encrypting certificates can be
'  retrieved from the Email object (methods: GetSignedByCert, GetEncryptedByCert;
'  properties: SignedBy, EncryptedBy, SignaturesValid, Decrypted, ReceivedSigned,
'  ReceivedEncrypted).

'  This example will explicity set AutoUnwrapSecurity to 1, even though it's
'  already the default value:
imap.AutoUnwrapSecurity = 1

'  The NumMessages property contains the number of messages in the selected mailbox.
numToFetch = imap.NumMessages
'  Download all the email in the Inbox.

Set bundle = imap.FetchSequence(1,numToFetch)
If (bundle Is Nothing ) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Loop over the bundle,

For i = 0 To bundle.MessageCount - 1

    Set email = bundle.GetEmail(i)

    outFile.WriteLine(email.From)
    outFile.WriteLine(email.Subject)

    '  At this point, if the email was signed and/or encrypted, it is already "unwrapped", i.e.
    '  the email is already decrypted and in a state as if it were never signed or encrypted.
    '  You may check to see if the email was received encrypted or signed, and if so,
    '  whether it was successfully unwrapped and who signed or encrypted it:
    If (email.ReceivedEncrypted = 1) Then

        outFile.WriteLine("This email was encrypted when received.")
        If (email.Decrypted = 1) Then
            outFile.WriteLine("This email was successfully decrypted.  It was encrypted by:")
            outFile.WriteLine(email.EncryptedBy)
        Else
            outFile.WriteLine("This email was not decrypted.")
        End If

    End If

    If (email.ReceivedSigned = 1) Then

        outFile.WriteLine("This email was signed when received.")
        If (email.SignaturesValid = 1) Then
            outFile.WriteLine("The signature was verified.  It was signed by:")
            outFile.WriteLine(email.SignedBy)
        Else
            outFile.WriteLine("The signature verification failed.")
        End If

    End If

    '  The email's body, HTML body, attachments, etc.
    '  are decrypted and available just like any non-encrypted email.

    outFile.WriteLine("--")

Next

'  Disconnect from the IMAP server.
imap.Disconnect 


outFile.Close