Process Bounced Email in IMAP

Download Chilkat Bounce ActiveX

Download Chilkat IMAP ActiveX

Reads an IMAP mailbox and determines which emails are bounces.

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set imap = CreateObject("Chilkat.Imap")
set bounce = CreateObject("Chilkat.Bounce")

'  Anything unlocks the component and begins a fully-functional 30-day trial.
success = imap.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

success = bounce.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox bounce.LastErrorText
    WScript.Quit
End If

'  Connect to an IMAP server.
success = imap.Connect("mail.chilkatsoft.com")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Login
success = imap.Login("admin@chilkatsoft.com","*myPassword5*")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Select an IMAP mailbox
success = imap.SelectMailbox("INBOX.bounceSamples")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  We can choose to fetch UIDs or sequence numbers.
fetchUids = 1
'  Get the message IDs of all the emails in the mailbox
Set messageSet = imap.Search("ALL",fetchUids)
If (messageSet Is Nothing ) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Fetch the emails into a bundle object:

Set bundle = imap.FetchBundle(messageSet)
If (bundle Is Nothing ) Then

    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Loop over the bundle and display the FROM and SUBJECT of each.

For i = 0 To bundle.MessageCount - 1

    Set email = bundle.GetEmail(i)

    bounce.ExamineMail email

    outFile.WriteLine("Subject: " & email.Subject)
    outFile.WriteLine("Bounce Type = " & bounce.BounceType _
         & ", email address = " & bounce.BounceAddress)

Next

'  Disconnect from the IMAP server.
imap.Disconnect 


outFile.Close