List IMAP Mailboxes

Download 32-bit Chilkat IMAP ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

List the mailboxes available within an IMAP account.

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set imap = CreateObject("Chilkat.Imap")

' Anything unlocks the component and begins a fully-functional 30-day trial.
success = imap.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

' Connect to an IMAP server.
success = imap.Connect("mail.chilkatsoft.com")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

' Login
success = imap.Login("admin@chilkatsoft.com","*myPassword5*")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

' The ListMailboxes method returns a Mailboxes object
' that contains the collection of mailboxes.
' It accepts two arguments: a refName and a wildcardedMailbox.

refName = ""
' refName is usually set to an empty string.
' A non-empty reference name argument is the name of a mailbox or a level of
' mailbox hierarchy, and indicates the context in which the mailbox
' name is interpreted.

' Select all mailboxes matching this pattern:
wildcardedMailbox = "*"

Set mboxes = imap.ListMailboxes(refName,wildcardedMailbox)
If (mboxes Is Nothing ) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

For i = 0 To mboxes.Count - 1
    outFile.WriteLine(mboxes.GetName(i))
Next

' Sample output looks like this:
' INBOX.vendors.shareit
' INBOX.oldSupport
' INBOX.vendors.paypal
' INBOX.sales
' INBOX.lists
' INBOX.Drafts
' INBOX.vendors.dell
' INBOX.Trash
' INBOX.invoiceRequests
' INBOX.purchases
' INBOX.vendors.inMotion
' INBOX.oldEmail
' INBOX.vendors
' INBOX.lists.python
' INBOX.vendors.myhosting
' INBOX.Templates
' INBOX.friends
' INBOX.bounceSamples
' INBOX.lists.ruby
' INBOX.vendors.peer1
' INBOX.Sent
' INBOX.Junk
' INBOX

' Disconnect from the IMAP server.
imap.Disconnect 


outFile.Close