Delete Email Individually (One at a time) from an IMAP Mailbox

Downloads email from an IMAP mailbox and deletes emails individually (one by one).

Download Chilkat IMAP ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set imap = CreateObject("Chilkat.Imap")

'  Anything unlocks the component and begins a fully-functional 30-day trial.
success = imap.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Connect to an IMAP server.
success = imap.Connect("mail.chilkatsoft.com")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Login
success = imap.Login("myLogin","myPassword")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Select an IMAP mailbox
success = imap.SelectMailbox("Inbox")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  We can choose to fetch UIDs or sequence numbers.
fetchUids = 1
'  Get the message IDs of all the emails in the mailbox
Set messageSet = imap.Search("ALL",fetchUids)
If (messageSet Is Nothing ) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Fetch the emails into a bundle object:

Set bundle = imap.FetchBundle(messageSet)
If (bundle Is Nothing ) Then

    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  To mark a complete set of emails for deletion, call SetFlags:
success = imap.SetFlags(messageSet,"Deleted",1)
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Messages can also be marked for deletion individually:
'  Loop over the bundle and mark each message for deletion.

For i = 0 To bundle.MessageCount - 1

    Set email = bundle.GetEmail(i)
    outFile.WriteLine(email.From)
    outFile.WriteLine(email.Subject)

    '  To delete this email, set the "Deleted" flag to 1.
    '  The email is not actually deleted until Expunge or
    '  ExpungeAndClose is called.
    success = imap.SetMailFlag(email,"Deleted",1)
    If (success <> 1) Then
        MsgBox imap.LastErrorText
        WScript.Quit
    End If

    outFile.WriteLine("--")

Next

success = imap.ExpungeAndClose()
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Disconnect from the IMAP server.
imap.Disconnect 


outFile.Close