Delete All IMAP Email

Demonstrates two ways to delete all email in a mailbox on an IMAP server.

Download Chilkat IMAP ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)


set imap = CreateObject("Chilkat.Imap")

'  Anything unlocks the component and begins a fully-functional 30-day trial.
success = imap.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Turn on session logging:
imap.KeepSessionLog = 1

'  Connect to an IMAP server.
success = imap.Connect("mail.chilkatsoft.com")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Login
success = imap.Login("myLogin","myPassword")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Select an IMAP mailbox
success = imap.SelectMailbox("Inbox.RubyMail")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Get the complete set of Uids for email in the selected mailbox.
Set messageSet = imap.GetAllUids()
If (messageSet Is Nothing ) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Set the Deleted flag for each message.
'  (ExpungeAndClose must be called to finalize the delete.)
success = imap.SetFlags(messageSet,"Deleted",1)
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Alternatively, the Deleted flag may be set for each UID
'  individiually, but this is less efficient:

n = messageSet.Count
For i = 0 To n - 1
    success = imap.SetFlag(messageSet.GetId(i),messageSet.HasUids,"Deleted",1)
    If (success <> 1) Then
        MsgBox imap.LastErrorText
        WScript.Quit
    End If

Next

'  Expunge and close the mailbox.
success = imap.ExpungeAndClose()
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Display the session log.
outFile.WriteLine(imap.SessionLog)

'  Disconnect from the IMAP server.
imap.Disconnect 


outFile.Close