Copy an Email from One Mailbox to Another

Copies an email from one IMAP folder to another. After running this example, copies of the email will be present in both source and destination folders.

Download Chilkat IMAP ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

'  This example copies an email from one mailbox to another.
set imap = CreateObject("Chilkat.Imap")

'  Anything unlocks the component and begins a fully-functional 30-day trial.
success = imap.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Turn on session logging:
imap.KeepSessionLog = 1

'  Connect to an IMAP server.
success = imap.Connect("mail.chilkatsoft.com")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Login
success = imap.Login("***","***")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Select an IMAP mailbox
success = imap.SelectMailbox("Inbox.testing.a")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

fetchUids = 1

'  Get the message IDs for all emails having "Re:" in the subject.
Set messageSet = imap.Search("SUBJECT Re:",fetchUids)
If (messageSet Is Nothing ) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Copy the messages from "Inbox.testing.a" to "Inbox.testing.b" in one call to CopyMultiple:
success = imap.CopyMultiple(messageSet,"Inbox.testing.b")
If (success <> 1) Then
    MsgBox imap.LastErrorText
    WScript.Quit
End If

'  Alternatively, loop over each message in the set and
'  copy each separately:

n = messageSet.Count
If (n > 0) Then
    For i = 0 To n - 1
        msgId = messageSet.GetId(i)
        isUid = messageSet.HasUids
        success = imap.Copy(msgId,isUid,"Inbox.testing.c")
        If (success <> 1) Then
            MsgBox imap.LastErrorText
            WScript.Quit
        End If

    Next
End If

'  Display the session log.
outFile.WriteLine(imap.SessionLog)

'  Disconnect from the IMAP server.
imap.Disconnect 


outFile.Close