Upload Files to Web Server

Demonstrates how to upload files from an application to a web server. Note: There must be something provided on the server-side to consume the upload. It could be an ASP or ASP.NET script, Perl, C++ CGI, PHP, Ruby, etc,. However, uploading via HTTP is not the same as uploading via FTP where the FTP server handles receiving the file and saving to disk.

The C# code behind http://www.chilkatsoft.com/receiveUpload.aspx may be found at this URL: C# to Receive Upload in ASP.NET.

Download Chilkat HTTP ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)


set http = CreateObject("Chilkat.Http")

'  Any string unlocks the component for the 1st 30-days.
success = http.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox http.LastErrorText
    WScript.Quit
End If

'  Build a HTTP request with the files to be uploaded:
set req = CreateObject("Chilkat.HttpRequest")
req.UseUpload 

'  The URL we'll be posting to is:
'  http://www.chilkatsoft.com/receiveUpload.aspx
'  Therefore, the path part of the URL is:
req.Path = "/receiveUpload.aspx"

'  Note: You may test uploads to this URL, but anything over 80K will be aborted on the receiving side.

'  Add some files to the request:
'  The 1st argument is an arbitrary name.  It's the POST form field name.
'  The 2nd argument is the filename currently existing on
'  the local filesystem.  It may include an absolute or relative
'  path, or no path at all if it's in the current working directory.
success = req.AddFileForUpload("file1","hamlet.xml")
If (success <> 1) Then
    MsgBox req.LastErrorText
    WScript.Quit
End If

success = req.AddFileForUpload("file2","dude.gif")
If (success <> 1) Then
    MsgBox req.LastErrorText
    WScript.Quit
End If

'  Send the HTTP POST and get the response.  Note: This is a blocking call.
'  The method does not return until the full HTTP response is received.

domain = "www.chilkatsoft.com"
port = 80
ssl = 0

Set resp = http.SynchronousRequest(domain,port,ssl,req)
If (resp Is Nothing ) Then
    outFile.WriteLine(http.LastErrorText)
Else
    '  Display the HTML source of the page returned.
    outFile.WriteLine(resp.BodyStr)
End If

outFile.Close