(VBScript) Twitter PIN-Based Authorization (Step 1)

Demonstrates the 1st step in Twitter PIN-based authorization using OAuth. The purpose of this step is to obtain a temporary request token that will be traded for an access token + secret in the final step. Once the access token + secret is obtained, the application can access the Twitter account in whatever ways it was authorized.

Note: This example requires Chilkat v11.0.0 or greater.

Chilkat ActiveX Downloads ActiveX for 32-bit and 64-bit Windows

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
'Create a Unicode (utf-16) output text file.
Set outFile = fso.CreateTextFile("output.txt", True, True)

success = 0

' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

set http = CreateObject("Chilkat.Http")

http.OAuth1 = 1
http.OAuthConsumerKey = "my-consumer-key"
http.OAuthConsumerSecret = "my-consumer-secret"

set req = CreateObject("Chilkat.HttpRequest")
req.HttpVerb = "POST"
req.ContentType = "application/x-www-form-urlencoded"

set resp = CreateObject("Chilkat.HttpResponse")
success = http.HttpReq("https://api.twitter.com/oauth/request_token",req,resp)
If (success = 0) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

If (resp.StatusCode = 200) Then

    oauthToken = resp.UrlEncParamValue(resp.BodyStr,"oauth_token")
    outFile.WriteLine("OAuth temporary request token = " & oauthToken)

    oauthTokenSecret = resp.UrlEncParamValue(resp.BodyStr,"oauth_token_secret")
    outFile.WriteLine("OAuth temporary token secret = " & oauthTokenSecret)

    oauthCbConfirmed = resp.UrlEncParamValue(resp.BodyStr,"oauth_callback_confirmed")
    outFile.WriteLine("OAuth callback confirmed  = " & oauthCbConfirmed)

    ' At this point, the end-user needs to browse to the following
    ' Twitter URL to log in to his/her Twitter account and get a PIN.
    ' 
    ' https://api.twitter.com/oauth/authenticate?oauth_token=OAUTH_TOKEN
    ' 
    ' (where OAUTH_TOKEN is replaced with the contents
    ' of the OAuth temporary request token.)

    ' Your application may have an embedded browser such
    ' that it automatically navigates to the above URL, or it may
    ' be necessary for the user to browse to this URL independently.

    ' Once the PIN is obtained, your application should provide a means
    ' for the end-user to enter it (by typing it into an input text box, for example), 
    ' and then Step 2 (the final step) can begin.

Else
    outFile.WriteLine(http.LastErrorText)
End If


outFile.Close