Tracing HTTP Redirects

Example to trace through HTTP redirects.

Download Chilkat HTTP ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set http = CreateObject("Chilkat.Http")

'  Any string unlocks the component for the 1st 30-days.
success = http.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox http.LastErrorText
    WScript.Quit
End If

url = "http://www.planyourweddingonline.co.za/"

'  The FollowRedirects property controls whether redirects
'  are automatically followed.  The default behavior is to
'  automatically follow redirects.

'  Explicitly set FollowRedirects so that redirects are NOT automatically taken:
http.FollowRedirects = 0

'  Send the HTTP GET and return the content in a string.
html = http.QuickGetStr(url)
If (html = vbNullString ) Then
    MsgBox http.LastErrorText
End If

status = http.LastStatus
outFile.WriteLine("HTTP Response Status: " & status)

'  The FinalRedirectUrl property will contain the redirect URL
'  If FollowRedirects was equal to 1, then all of the
'  intermediate redirects (if any) would be followed until
'  there were no more redirects.  However, because
'  FollowRedirects is not 1, FinalRedirectUrl contains
'  the next redirect URL.
outFile.WriteLine("Redirect URL: " & http.FinalRedirectUrl)

loopCount = 0

Do While (status = 302)
    url = http.FinalRedirectUrl
    html = http.QuickGetStr(url)
    If (html = vbNullString ) Then
        MsgBox http.LastErrorText
        Exit Do
    End If

    status = http.LastStatus
    outFile.WriteLine("Redirect URL: " & http.FinalRedirectUrl)

    '  You may wish to check that if FinalRedirectUrl
    '  equals the URL just retrieved.  If so, then break out of the
    '  loop.  (This check is omitted in this example.)

    '  Instead, this example will prevent infinite loops by
    '  keeping a loopCount and only allows following a max
    '  of 10 redirects:
    loopCount = loopCount + 1
    If (loopCount > 10) Then
        Exit Do
    End If

Loop
outFile.Close