HTTP Session with Cookies

How to keep a session with cookies. Demonstrates how to login to WordPress.

Download Chilkat HTTP ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set req = CreateObject("Chilkat.HttpRequest")
set http = CreateObject("Chilkat.Http")

'  Any string unlocks the component for the 1st 30-days.
success = http.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox http.LastErrorText
    WScript.Quit
End If

'  This example will demonstrate maintaining a session with
'  cookies by doing a simple login to a WordPress blog.
'  Indicate that cookies are to be saved and re-sent.
'  Instead of using a cookie file, you may use the string "memory"
'  to save cookies to memory.
http.CookieDir = "memory"
http.SendCookies = 1
http.SaveCookies = 1

'  Let's first hit the chilkat.wordpress.com login page to make sure
'  we have any initial cookies...

html = http.QuickGetStr("http://chilkat.wordpress.com/wp-login.php")
If (html = vbNullString ) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

'  Build an HTTP POST request to login
req.UsePost 
req.Path = "/wp-login.php"
req.AddParam "log","chilkat"
req.AddParam "pwd","myPassword"
req.AddParam "rememberme","forever"
req.AddParam "wp-submit","Login"
req.AddParam "redirect_to","/wp-admin/"

req.AddHeader "Referer","http://chilkat.wordpress.com/wp-login.php"

'  Send the HTTP POST and get the response.  Note: This is a blocking call.
'  The method does not return until the full HTTP response is received.

domain = "chilkat.wordpress.com"
port = 80
ssl = 0

Set resp = http.SynchronousRequest(domain,port,ssl,req)
If (resp Is Nothing ) Then
    outFile.WriteLine(http.LastErrorText)
    WScript.Quit
End If

'  Is this a 302 redirect?
If (resp.StatusCode = 302) Then

    '  Get the redirect URL:

    redirectUrl = resp.GetHeaderField("Location")

    html = http.QuickGetStr(redirectUrl)
    If (html = vbNullString ) Then
        outFile.WriteLine(http.LastErrorText)
    Else
        outFile.WriteLine(html)
    End If

Else
    outFile.WriteLine(resp.BodyStr)
End If

outFile.Close