Amazon AIMS HTTPS POST

Demonstrates a simple post to the Amazon Inventory Management System (AIMS) API using Chilkat HTTP.

Download Chilkat HTTP ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set req = CreateObject("Chilkat.HttpRequest")
set http = CreateObject("Chilkat.Http")

'  Any string unlocks the component for the 1st 30-days.
success = http.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox http.LastErrorText
    WScript.Quit
End If

'  Before doing the POST, do a simple GET for the purpose of obtaining a Cookie.
'  The Cookie contains a session-id and a session-id-time, and these values must
'  be current.

'  The CookieDir may be set to "memory" to keep an in-memory cache of cookies.
'  Alternatively, you may set it to a directory, such as "c:/temp/cookies".  If you do that,
'  you can visually browse the cookies which will appear as XML files in the CookieDir.
http.CookieDir = "memory"

'  Tell the HTTP component to save any cookies received.  Also tell the component to
'  re-send cookies with subsequent GETs and POSTs.
http.SendCookies = 1
http.SaveCookies = 1

'  Do a GET to retrieve our Cookie...

html = http.QuickGetStr("https://secure.amazon.com/exec/panama/seller-admin/manual-reports/get-report-status")

'  Build an HTTP POST Request:
req.UsePost 
req.Path = "/exec/panama/seller-admin/manual-reports/get-report-status"

'  Setting your login/password causes Chilkat to automatically add the Authorization header:
http.Login = "YourLoginEmailAddress"
http.Password = "YourPassword"

'  NOTE: Do not explicitly add the Cookie header.  It is added automatically by Chilkat HTTP.
req.AddHeader "Content-Type","text/xml"

req.AddHeader "NumberofReports","2"
req.AddHeader "ReportName","OpenListingsLite"

'  Send the HTTP POST and get the response.  Note: This is a blocking call.
'  The method does not return until the full HTTP response is received.

domain = "secure.amazon.com"
port = 443
ssl = 1

Set resp = http.SynchronousRequest(domain,port,ssl,req)
If (resp Is Nothing ) Then
    outFile.WriteLine(http.LastErrorText)
Else
    '  Display the XML returned.
    outFile.WriteLine(resp.BodyStr)
End If

outFile.Close