Verify FTP SSL Server Certificate

This example demonstrates how to verify the FTP server's certificate and authenticity. The intent is to verify the authenticity of the server before passing a login/password to it.

Download Chilkat FTP2 ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set ftp = CreateObject("Chilkat.Ftp2")

'  Any string unlocks the component for the 1st 30-days.
success = ftp.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

ftp.Hostname = "ftp.myftpserver.com"
ftp.Username = "myUsername"
ftp.Password = "myPassword"

'  Establish an AUTH SSL secure channel after connection
'  on the standard FTP port 21.
ftp.AuthSsl = 1

'  The Ssl property is for establishing an implicit SSL connection
'  on port 990.  Do not set it.
ftp.Ssl = 0

'  Indicate that the FTP server must have a verifiable SSL certificate.
'  Do not accept self-signed certs or certificates that are
'  expired, revoked, or cannot be verified to a root authority:
ftp.RequireSslCertVerify = 1

'  You may also set a requirement.  In this example,
'  the certificate's Common Name (CN) must match the
'  required string exactly:
ftp.SetSslCertRequirement "subjectcn","Chilkat Software, Inc."

'  Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
Else
    '  LastErrorText contains information even when
    '  successful. This allows you to visually verify
    '  that the secure connection actually occurred.
    outFile.WriteLine(ftp.LastErrorText)
End If

'  After logging on, you may examine the FTP server's cert:

Set cert = ftp.GetSslServerCert()
If (cert Is Nothing ) Then
    MsgBox "No server certificate!"
Else
    '  Display the distinguished name of the SSL cert.
    MsgBox cert.SubjectDN
End If

MsgBox "Secure FTP Channel Established!"

'  Do whatever you're doing to do ...
'  upload files, download files, etc...

ftp.Disconnect 
outFile.Close