Restart/Resume FTP Upload

Download 32-bit Chilkat FTP2 ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

Demonstrates how to restart / resume an FTP upload.

set ftp = CreateObject("Chilkat.Ftp2")

'  Any string unlocks the component for the 1st 30-days.
success = ftp.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

ftp.Hostname = "ftp.chilkatsoft.com"
ftp.Username = "****"
ftp.Password = "****"

'  Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

'  Change to the remote directory where the file will be uploaded.
success = ftp.ChangeRemoteDir("temp")
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

'  In this example, assume that a previous FTP upload failed,
'  and the incomplete file (bigFile.zip) exists on the FTP server.
'  You only need to set the RestartNext property to resume
'  the upload.  When RestartNext is set, the next call
'  to PutFile (or PutFileFromBinaryData, PutFileFromTextData)
'  will automatically resume the upload from the point of failure.
'  (The way it works is that the FTP component sends a "SIZE"
'  command to the FTP server to find out how many bytes of
'  the file already exist on the server.  It then begins
'  uploading from that point.

'  Note: After PutFile is called, the RestartNext property
'  is automatically set to false.
ftp.RestartNext = 1

'  Upload a file with restart.
localFilename = "bigFile.zip"
remoteFilename = "bigFile.zip"

success = ftp.PutFile(localFilename,remoteFilename)
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

ftp.Disconnect 

MsgBox "File Uploaded!"