Upload to Tumbleweed SecureTransport FTPS Server

Demonstrates how to connect, authenticate, and upload file to a Tumbleweed Secure Transport SSL FTP Server. Instead of providing a login name and password, you pass the string "site-auth" for the username, and an empty string for the password. You must also provide a client-side digital certificate -- as the certificate's credentials and validity are used to authenticate.

Download 32-bit Chilkat FTP2 ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set ftp = CreateObject("Chilkat.Ftp2")

'  Any string unlocks the component for the 1st 30-days.
success = ftp.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

'  This code has been tested with the Tumbleweed server
'  at sft.wellsfargo.com
ftp.Hostname = "sft.wellsfargo.com"

'  Use these exact strings for the username and password:
ftp.Username = "site-auth"
ftp.Password = ""

'  Establish an AUTH SSL secure channel after connecting.
'  Your client-side certificate is used for authentication when
'  the SSL channel is established.
ftp.AuthSsl = 1

'  The Ssl property is for establishing an implicit SSL connection
'  on port 990.  Do not set it.
ftp.Ssl = 0

'  Load a certificate from a .pfx
'  A PFX may contain several certs, including the certificates
'  in a chain of authority.
set certStore = CreateObject("Chilkat.CertStore")

password = "***"
'  Load the certs from a PFX into an in-memory certificate store:
success = certStore.LoadPfxFile("my.pfx",password)
If (success <> 1) Then
    outFile.WriteLine(certStore.LastErrorText)
    WScript.Quit
End If

'  Find the exact cert we'll use:

' cert is a Chilkat.Cert
Set cert = certStore.FindCertBySubject("My Certificate 123 ABC")
If (cert Is Nothing ) Then
    outFile.WriteLine("Certificate not found!")
    WScript.Quit
End If

'  Tell the Chilkat FTP2 component to use the client-side
'  cert for the SSL connection:
ftp.SetSslClientCert cert

'  Connect and authenticate with the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
Else
    '  LastErrorText contains information even when
    '  successful. This allows you to visually verify
    '  that the secure connection actually occurred.
    outFile.WriteLine(ftp.LastErrorText)
End If

MsgBox "Secure FTP Channel Established!"

'  Change to the remote directory where the file will be
'  uploaded.  If your file is to be uploaded to the FTP user
'  account's home directory, this is not necessary.
success = ftp.ChangeRemoteDir("someSubDir")
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

'  You may include an absolute or relative path with the
'  local filename.  If no path is included, the file should
'  be present in the current working directory of the calling
'  process.
localFilename = "someFile.dat"
remoteFilename = "someFile.dat"

'  Upload the file.
success = ftp.PutFile(localFilename,remoteFilename)
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

ftp.Disconnect 
outFile.Close