Quote and SendCommand

Demonstrate the Quote and SendCommand methods.

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set ftp = CreateObject("Chilkat.Ftp2")

'  Any string unlocks the component for the 1st 30-days.
success = ftp.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

ftp.Hostname = "www.myftpserver.com"
ftp.Username = "****"
ftp.Password = "****"

'  Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

'  Tell the FTP object to keep an in-memory session log
'  so we can see the commands sent to the server,
'  and the responses received back.
ftp.KeepSessionLog = 1

'  Change the current remote directory via the Quote method:
success = ftp.Quote("CWD junk")
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

'  Move back up
'  In this case, ChangeRemoteDir sends "CWD .." to the FTP server.
success = ftp.ChangeRemoteDir("..")
If (success <> 1) Then
    outFile.WriteLine(ftp.LastErrorText)
    WScript.Quit
End If

'  Do the same via the SendCommand method where the
'  raw FTP server response is returned:

serverResponse = ftp.SendCommand("CWD junk")
If (serverResponse = vbNullString ) Then
    outFile.WriteLine(ftp.LastErrorText)
Else
    outFile.WriteLine(serverResponse)
End If

ftp.Disconnect 

outFile.WriteLine("Session Log:")
outFile.WriteLine(ftp.SessionLog)

outFile.Close