ProgressMonSize Property

Demonstrates the case where the ProgressMonSize property is required to monitor the progress of FTP downloads.

When a file is downloaded, most FTP servers will indicate the file size in the intermediate "150" response. For example:

RETR hamlet.xml
150 Opening BINARY mode data connection for hamlet.xml (279658 Bytes).
226 Transfer complete.

However, some FTP servers do not provide the file size. For example, from a FileZilla server:

RETR files.txt
150 Connection accepted
226 Transfer OK

If the file size is not present, the component does not know how many bytes are forthcoming, and therefore it is not possible to monitor percentage completion progress -- unless the application provides a little help by setting the ProgressMonSize property just prior to calling GetFile.

The application should set the ProgressMonSize to the size indicated by GetSizeByName as demonstrated in this example.

Download Chilkat FTP2 ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set ftp = CreateObject("Chilkat.Ftp2")

'  Any string unlocks the component for the 1st 30-days.
success = ftp.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

ftp.Hostname = "ftp.chilkatsoft.com"
ftp.Username = "****"
ftp.Password = "****"

ftp.KeepSessionLog = 1

'  Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

'  Change to the remote directory where the file is located.
'  This step is only necessary if the file is not in the root directory
'  for the FTP account.
success = ftp.ChangeRemoteDir("junk")
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

'  Download a file.
localFilename = "hamlet.xml"
remoteFilename = "hamlet.xml"

'  If the FTP server does not supply the file size in the "150"
'  intermediate response (to the RETR command), then tell
'  the component how many bytes are forthcoming (if your
'  application wishes to monitor the progress as a percentage
'  completion).

fileSize = ftp.GetSizeByName(remoteFilename)
ftp.ProgressMonSize = fileSize

success = ftp.GetFile(remoteFilename,localFilename)
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

outFile.WriteLine(ftp.SessionLog)

ftp.Disconnect 


outFile.Close