Get FTP Directory Listing Information

VBScript example showing how to get information about files and subdirectories in the current remote FTP directory.

Download Chilkat FTP2 ActiveX

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set ftp = CreateObject("Chilkat.Ftp2")

'  Any string unlocks the component for the 1st 30-days.
success = ftp.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

ftp.Hostname = "www.example-code.com"
ftp.Username = "****"
ftp.Password = "****"

'  Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

'  The ListPattern property is our directory listing filter.
'  The default value is "*", which includes everything.
outFile.WriteLine(ftp.ListPattern)

'  To get file and sub-directory information, simply
'  loop from 0 to ftp.NumFilesAndDirs - 1

n = ftp.NumFilesAndDirs
If (n < 0) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

If (n > 0) Then
    For i = 0 To n - 1

        '  Display the filename
        outFile.WriteLine(ftp.GetFilename(i))

        '  Display the file size (in bytes)
        outFile.WriteLine(ftp.GetSize(i))

        '  Is this a sub-directory?
        If (ftp.GetIsDirectory(i) = 1) Then
            outFile.WriteLine(".. this is a sub-directory")
        End If

        outFile.WriteLine("--")
    Next
End If

outFile.WriteLine("-----------------------------------")

'  Changing the ListPattern automatically changes the value
'  of the NumFilesAndDirs property.  Only files and directories
'  matching the ListPattern are returned.
ftp.ListPattern = "*.asp"
n = ftp.NumFilesAndDirs
If (n < 0) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

If (n > 0) Then
    For i = 0 To n - 1

        '  Display the filename
        outFile.WriteLine(ftp.GetFilename(i))

        '  Display the file size (in bytes)
        outFile.WriteLine(ftp.GetSize(i))

        outFile.WriteLine("--")
    Next
End If

ftp.Disconnect 
outFile.Close