CRLF Mode

The CrlfMode property applies when downloading files in ASCII mode. If CrlfMode is set to 0 (the default), then the ASCII transfer happens normally without alteration. A value of 1 converts all line endings to CR+ LF. A value of 2 converts all line endings to LF-only. A value of 3 converts all line endings to CR-only.

Download 32-bit Chilkat FTP2 ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

Dim fso, outFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set outFile = fso.CreateTextFile("output.txt", True)

set ftp = CreateObject("Chilkat.Ftp2")

'  Any string unlocks the component for the 1st 30-days.
success = ftp.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

ftp.Hostname = "ftp.chilkatsoft.com"
ftp.Username = "MyLogin"
ftp.Password = "MyPassword"

'  Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

'  Set the transfer mode to ASCII
success = ftp.SetTypeAscii()
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

'  Set the CrlfMode to ensure that line endings are CR+LF:
ftp.CrlfMode = 1

'  CrlfMode line ending settings:
'  0 = do ASCII transfer without alteration.
'  1 = CR+LF
'  2 = LF-only
'  3 = CR-only

'  Change to the remote directory where the file will be uploaded.
success = ftp.ChangeRemoteDir("junk")
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

localFilename = "hamlet.xml"
remoteFilename = "hamlet.xml"

'  Turn on session logging for the upload:
ftp.KeepSessionLog = 1

'  Download a file.
success = ftp.GetFile(remoteFilename,localFilename)
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    WScript.Quit
End If

'  View the session log.  You can verify visually that
'  the transfer was in ascii mode.
outFile.WriteLine(ftp.SessionLog)

ftp.Disconnect 

MsgBox "File Downloaded!"
outFile.Close